Maustasten sicher abfragen

Frank A.

Code

' Maustasten sicher abfragen (w) Frank Abbing
'
Cls


UserMessages $201,$204,$207,$202,$205,$208


While 1


  WaitInput
  Case %key=2:Break


  If %umessage=$201
    Print "Links gedrückt."
  ElseIf %umessage=$204
    Print "Rechts gedrückt."
  ElseIf %umessage=$207
    Print "Mitte gedrückt."
  ElseIf %umessage=$202
    Print "Links losgelassen."
  ElseIf %umessage=$205
    Print "Rechts losgelassen."
  ElseIf %umessage=$208
    Print "Mitte losgelassen."
  EndIf

Endwhile


End

Alles anzeigen

Werbepost

Hallo!

Wenn du gerade an deiner Website arbeitest oder dein aktuelles Hosting überdenkst: Wir betreiben mit NetzLiving eine Hosting-Plattform, die speziell auf Performance, Sicherheit und einfache Verwaltung ausgelegt ist.

✔️ Schnelle Ladezeiten (optimiert für WordPress, WoltLab & Co.)
✔️ Deutsche Server & DSGVO-konform
✔️ Persönlicher Support (kein 0815-Ticket-System)

Mehr erfahren

Wenn du Fragen hast, kannst du dich gerne jederzeit an @Maximilian Rupp wenden

Hinweis:

p. specht

SUPERST! Danke!

p. specht

Hab mir erlaubt, die Beiträge von Frank und Dieter zu kombinieren und um die "Lebende Schleife" zu ergänzen :D. Funktionierte im Interpreter-Modus auf Anhieb total einwandfrei.

'Known Issues' dieser Beta-Version: Compiliert, wird die Abfrage so schnell, daß sowohl prellende Tasten Mehrfachevents auslösen, als auch jeder weitere Programmstart (Vermutung) zusätzliche Eventhandlers gleicher Funktionsnummer installiert. Folge: Es werden Doppel-Events empfangen! Derzeit einzige Abhilfe: In der Compilerversion Software-Entprellung durch Prüfung auf doppelte Events. Anmerkung: Frank´s Routine im Beitrag vorher funktioniert dagegen auch compiliert einwandfrei.

Weiterer Punkt auf der ToDo-Liste: Checken, OB überhaupt eine Mitteltaste bzw. ein Mausrad vorhanden ist... Weiss jemand Rat?

Code

windowtitle "TTMS - The Total Mouse Solution - Version 1 beta"
' Aus den Teilen: Maustasten sicher abfragen (w) Frank Abbing,
' und: Mausrad hoch und runter von Dieter Zornow
' zusammengestellt und um "Lebende Schleife" (R) sowie
' um sauberes Beenden(TM) ergänzt.
Cls
declare x%,y%
UserMessages $201,$204,$207,$202,$205,$208,$20A
SetTimer 10
While 1
  WaitInput
  Case %key=2:Break


  If %umessage=$201
    Print "Links gedrückt."
  ElseIf %umessage=$204
    Print "Rechts gedrückt."
  ElseIf %umessage=$207
    Print "Mitte gedrückt."
  ElseIf %umessage=$202
    Print "Links losgelassen."
  ElseIf %umessage=$205
    Print "Rechts losgelassen."
  ElseIf %umessage=$208
    Print "Mitte losgelassen."
  ElseIf %UMESSAGE = $20A
         IF HIWORD(&UWPARAM)=120
             PRINT "Rad hoch   "
         ELSE
             PRINT "Rad runter "
         ENDIF
   EndIf


' Lebende Schleife
x%=%Pos:y%=%csrlin       ' Merk dir wo du warst
Locate 1,2:print x%,y%;"  ";  ' und gib HIER kurz mal was aus
Locate 2,2:print %mouseX;":";%mouseY;"   "
locate y%,x%             ' Restore, wo du grad warst
print "#";               ' Beliebige andere, quasi parallel laufende Aktion


Endwhile
UserMessages 0
KillTimer
End

Alles anzeigen

Andreas Miethe

Zitat von p. specht;732249

Weiterer Punkt auf der ToDo-Liste: Checken, OB überhaupt eine Mitteltaste bzw. ein Mausrad vorhanden ist... Weiss jemand Rat?

Das sollte doch nicht so schwierig sein.

Code

$H Windows.ph
cls
If ~GetSystemMetrics(19)
Print "Mausrad vorhanden"
Else
Print "keine Mausrad"
Endif
Print ~GetSystemMetrics(43);" Tasten an der Maus installiert"
Waitinput

Frank A.

Zitat

Das sollte doch nicht so schwierig sein.

Vielleicht doch.

Bei meinem Trackball wird ein Mausrad angeblich erkannt, zudem 5 Maustasten...

Frank A.

Meiner Meinung nach müsste dein Code eher so lauten:

Code

$H Windows.ph


Declare x&
Cls


If ~GetSystemMetrics(91)
  Inc x&
  Print "Horizontales Mausrad vorhanden"
EndIf
If ~GetSystemMetrics(75)
  Inc x&
  Print "Vertikales Mausrad vorhanden"
EndIf


IfNot x&
  Print "Kein Mausrad vorhanden."
EndIf


Print ~GetSystemMetrics(43);" Tasten an der Maus installiert"


WaitInput
End

Alles anzeigen

SM_MOUSEHORIZONTALWHEELPRESENT=91
SM_MOUSEWHEELPRESENT=75

SM_MOUSEPRESENT ist nur eine Abfrage, ob eine Maus existiert. MS schreib dazu aber, dass diese fast immer existent ist, und sei es nur virtuell...

Bei den Tasten baut die API bei mir aber Mist. Mein Trackback hat die beiden normalen Buttons links und rechts, und zwei Zusatzbuttons. Vier, nicht fünf.
Absolute Sicherheit gibt es also nicht.

Unregistriert

API sagt was Treiber gibt und 5 Mäuse mit 1 Treiber -> ungenau.

Andreas Miethe

Zitat von Frabbing;732347

SM_MOUSEPRESENT ist nur eine Abfrage, ob eine Maus existiert. MS schreib dazu aber, dass diese fast immer existent ist, und sei es nur virtuell...

Dashabe ich auch gelesen Im PSDK. Da stand aber auch

SM_MOUSEWHEELPRESENT
19

Dann ist da wohl ein Fehler drin.

Wie dem auch sei, ich habe kein Mausrad, bekomme aber trotzdem angezeigt, dass eins vorhanden ist.

Frank A.

Die API scheint also keine sichere Methode zu sein.

Zitat

API sagt was Treiber gibt und 5 Mäuse mit 1 Treiber -> ungenau.

5 Mäuse? Gemeint sind aber Maustasten. Ich hab 4, aber die API meldet 5.

p. specht

1. Kann man das vielleicht aufdröseln in folgende Fälle:
Funkmäuse? USB-Mäuse? Mausport-Mäuse? Serielle Mäuse? Trackballs?
Was habt ihr denn?

2. Frage an die Generaliät: Woher kommen die Doppelevents beim Compilieren?
Gibts eine Methode, sie elegant loszuwerden? Einen zusätzlichen Api-Aufruf vielleicht?

Gruss

Andreas Miethe

Ich habe ein Touchpad am Laptop. Definitiv kein Rad. Die Radfunktion wird aber wohl emuliert über zwei sensitive Scroll-Leisten am Touchpad.

Kannst Du damit was anfangen ?

Jedenfalls funktioniert die Abfrage in Deinem o. Programm. Scrolldown und Scrollup wird angezeigt.

Frank A.

Zitat

2. Frage an die Generaliät: Woher kommen die Doppelevents beim Compilieren?
Gibts eine Methode, sie elegant loszuwerden? Einen zusätzlichen Api-Aufruf vielleicht?

Das liegt vielleicht am Timer, ich selber hab keine Doppelevents beobachtet.

p. specht

CRAZY MOUSE 1.1 beta

Es ist FAST geschafft: Die Interpreterversion verhält sich nun sehr ähnlich wie die Compilerversion. Bekannter Schönheitsfehler: In der Compilerversion kommt trotz ausdrücklichem 'Debounce' in Profancode VOR dem nächsten "Rad hoch" noch einmal ein "Rad runter" - Schleierhaft, wieso. Mausrad-Anwendungen in Profan sind aber in der Regel nicht so kritisch.

Code

$H Windows.ph
Def IsMouseSwapped(0) ~GetSystemMetrics(~SM_SWAPBUTTON)
'0 = Rechtmaus/1 = Linksmaus


windowtitle "Crazy Mouse - Version 1.0 beta"
' Aus den Teilen: IsMouseSwapped() von David Strutz,
' Maustasten sicher abfragen (w) von Frank Abbing,
' Mausrad hoch und runter von Dieter Zornow
' CheckIfMousewheel/MiddleKey von Andreas Miethe samt 
' Franks improvement betr. Horizontal-Mausrad/Trackball,
' zusammengestellt und um "Lebende Schleife", "Debounce" 
' und "Sauberes Beenden"(TM) ergänzt von P. Specht 2009-09


Cls
declare x%,y%,z%,LM%,FLT%
UserMessages $201,$204,$207,$202,$205,$208,$20A
if IsMouseSwapped()=0
   print "             Rechtshänder-Maus, keine Tastenvertauschung"
else
   print "             Linkshänder-Maus, Tasten R-L-vertauscht" 
endif


z%=0
If ~GetSystemMetrics(91)
  Inc z%
  Print "             Horizontales Mausrad vorhanden"
EndIf
If ~GetSystemMetrics(75)
  Inc z%
  Print "             Vertikales Mausrad vorhanden"
EndIf
IfNot z%
  Print "             Kein Mausrad vorhanden."
EndIf


z%=~GetSystemMetrics(43)
print "             ";z%;" Tasten an der Maus installiert"
flt%=2


SetTimer 1
While 1


WaitInput


  If %UMESSAGE = $20A
       IF HIWORD(&UWPARAM)=120
          PRINT " Rad hoch   ":FLT%=2
       ELSE
          if flt% : flt%=abs(flt%)-1
          elseif flt%=0: PRINT " Rad runter " 
          endif
       ENDIF
  ENDIF


  If %umessage=$201
     ifnot LM%=1:Print " Links gedrückt.   ":LM%=1:endif
  ElseIf %umessage=$204
     ifnot LM%=4:Print " Rechts gedrückt.  ":LM%=4:endif
  ElseIf %umessage=$207
     ifnot LM%=7:Print " Mitte gedrückt.   ":LM%=7:endif
  ElseIf %umessage=$202
     ifnot LM%=2:Print " Links losgelassen.":LM%=2:endif
  ElseIf %umessage=$205
     ifnot LM%=5:Print " Rechts losgelassen.":LM%=5:endif
  ElseIf %umessage=$208
     ifnot LM%=8:Print " Mitte losgelassen. ":LM%=8:endif
  EndIf


  if %key=2 OR %key=27:Break:endif


' Lebende Schleife
x%=%Pos:y%=%csrlin       ' Merk dir wo du warst
Locate 1,2:print x%,y%;"  ";  ' und gib HIER kurz mal was aus
Locate 2,2:print %mouseX;":";%mouseY;"   "


locate y%,x%             ' Restore, wo du grad warst
print "#";               ' Beliebige weiterlaufende Aktion
                         ' die selbst nicht allzu lange dauert
Endwhile
UserMessages 0
KillTimer
End

Alles anzeigen

P.S.: Achtung beim Maustasten-Zählen: Auch ein Mausrad kann man klicken!

Frank A.

Mausrad kann ich nicht testen. Hab - wie gesagt - keines.

p. specht

Kann man nicht die Trackballs selbst zusätzlich auch klicken?

Frank A.

Ich bevorzuge eher die spartanischen Varianten, die haben das zumindest nicht...
http://www.logitech.com/index.cfm/mice…s/4680&cl=us,en

Gehen auch quasi nicht kaput, wirklich unverwüstlich.

p. specht

Geiles Teil!!!

Frank A.

Ja, man will keine Maus mehr haben, wenn man das mal hatte.
Aber das driftet schon wieder viel zu weit vom Thema ab... :wurm:

p. specht

Im obigen Programmchen würde ich mir gerne die Einbindung der ganzen Header-Datei ersparen, meine Ersatzversuche produzieren aber leider nur Voll-Abstürze. Statt

$H Windows.ph
Def IsMouseSwapped(0) ~GetSystemMetrics(~SM_SWAPBUTTON)

sollte doch sowas ähnliches wie

Def IsMouseSwapped(0) External(~user32,"GetSystemMetrics",23);

auch funktionieren. Will aber nicht... Bitte um Hinweise!
EDIT: Tschisas, ~user32 braucht ja auch die Headerdatei... GRMLFGBZZZ

Frank A.

So gehts:

Code

Def GetSystemMetrics(1) !"user32","GetSystemMetrics"
Def IsMouseSwapped(0) GetSystemMetrics(23)


Cls
Print IsMouseSwapped()


WaitInput

Jetzt mitmachen!