Farb-Wort-Interferenz

PROC FWI
declare i%,ende%,wort$[],anzworte%,farbe%[],anzfarben%,aktwort%,aktfarbe%,akthgfarbe%,modus%,anzmodi%,texthoehe%,altfarbe%,altwort%,aktpos%,pwort$[],anzpworte%,posx%[],posy%[],anzpos%,altpos%,aktpwort%,altpwort%,althgfarbe%
'Variablen initialisieren
texthoehe%=40 'texthoehe%=(@height(%HWnd)\4)
anzmodi%=4
modus%=1 '1=nur Farben, 2=nur Positionen, 3=Farben und Positionen, 4=Farben, Postitionen und Hintergrundfarben
wort$[1]="rot"
wort$[2]="grün"
wort$[3]="blau"
wort$[4]="gelb"
wort$[5]="braun"
wort$[6]="schwarz"
wort$[7]="violett"
wort$[8]="grau"
wort$[9]="weiß"
anzworte%=9
pwort$[1]="links"
pwort$[2]="oben"
pwort$[3]="rechts"
pwort$[4]="unten"
pwort$[5]="mitte"
anzpworte%=5
farbe%[1]=@rgb(255,0,0) 'rot
farbe%[2]=@rgb(0,185,0) 'grün
farbe%[3]=@rgb(0,0,255) 'blau
farbe%[4]=@rgb(255,255,0) 'gelb
farbe%[5]=@rgb(100,45,25) 'braun
farbe%[6]=@rgb(0,0,0) 'schwarz
farbe%[7]=@rgb(255,0,255) 'violett
farbe%[8]=@rgb(100,100,100) 'grau
farbe%[9]=@rgb(255,255,255) 'weiß
anzfarben%=9
posx%[1]=200:posy%[1]=@height(%HWnd)\2 'links
posx%[2]=@width(%HWnd)\2:posy%[2]=150 'oben
posx%[3]=@width(%HWnd)-200:posy%[3]=@height(%HWnd)\2 'rechts
posx%[4]=@width(%HWnd)\2:posy%[4]=@height(%HWnd)-150-(texthoehe%\2) 'unten
posx%[5]=@width(%HWnd)\2:posy%[5]=@height(%HWnd)\2 'mitte
anzpos%=5
'Eingabehandling
ende%=0
whilenot ende%
if modus%=1' nur Farben
aktwort%=@rnd(anzworte%)+1
aktfarbe%=@rnd(anzfarben%-1)+1
while (aktfarbe%=aktwort%) or (aktfarbe%=altfarbe%) or (aktwort%=altwort%)
aktwort%=@rnd(anzworte%)+1
aktfarbe%=@rnd(anzfarben%-1)+1
endwhile
cls @rgb(255,255,255)
textcolor @rgb(0,0,0),-1
usefont "Arial",16,0,0,0,0
drawtext 10,(@height(%HWnd)-26),"Modus 1: Farben (M=Moduswechsel)",0
textcolor farbe%[aktfarbe%],-1
usefont "Arial",texthoehe%,0,1,0,0
drawtext (@width(%HWnd)\2),((@height(%HWnd)\2)-(texthoehe%\2)),wort$[aktwort%],6
altwort%=aktwort%
altfarbe%=aktfarbe%
elseif modus%=2 'nur Positionen
aktpwort%=@rnd(anzpworte%)+1
aktpos%=@rnd(anzpos%)+1
while (aktpwort%=aktpos%) or (aktpos%=altpos%) or (aktpwort%=altpwort%)
aktpwort%=@rnd(anzpworte%)+1
aktpos%=@rnd(anzpos%)+1
endwhile
cls @rgb(255,255,255)
textcolor @rgb(0,0,0),-1
usefont "Arial",16,0,0,0,0
drawtext 10,(@height(%HWnd)-26),"Modus 2: Positionen (M=Moduswechsel)",0
textcolor @rgb(0,0,0),-1
usefont "Arial",texthoehe%,0,1,0,0
drawtext posx%[aktpos%],posy%[aktpos%],pwort$[aktpwort%]
altpos%=aktpos%
altpwort%=aktpwort%
elseif modus%=3' Farben und Positionen
aktwort%=@rnd(anzworte%)+1
aktfarbe%=@rnd(anzfarben%-1)+1
aktpwort%=@rnd(anzpworte%)+1
aktpos%=@rnd(anzpos%)+1
while (aktfarbe%=aktwort%) or (aktfarbe%=altfarbe%) or (aktwort%=altwort%) or (aktpwort%=aktpos%) or (aktpos%=altpos%) or (aktpwort%=altpwort%)
aktwort%=@rnd(anzworte%)+1
aktfarbe%=@rnd(anzfarben%-1)+1
aktpwort%=@rnd(anzpworte%)+1
aktpos%=@rnd(anzpos%)+1
endwhile
cls @rgb(255,255,255)
textcolor @rgb(0,0,0),-1
usefont "Arial",16,0,0,0,0
drawtext 10,(@height(%HWnd)-26),"Modus 3: Farben & Positionen (M=Moduswechsel)",0
textcolor farbe%[aktfarbe%],-1
usefont "Arial",texthoehe%,0,1,0,0
drawtext posx%[aktpos%],posy%[aktpos%],wort$[aktwort%]+" "+pwort$[aktpwort%],6
altwort%=aktwort%
altfarbe%=aktfarbe%
altpos%=aktpos%
altpwort%=aktpwort%
elseif modus%=4 'Farben, Positionen und Hintergrundfarben
aktwort%=@rnd(anzworte%)+1
aktfarbe%=@rnd(anzfarben%)+1
akthgfarbe%=@rnd(anzfarben%)+1
aktpwort%=@rnd(anzpworte%)+1
aktpos%=@rnd(anzpos%)+1
while (aktfarbe%=aktwort%) or (aktwort%=akthgfarbe%) or (aktfarbe%=akthgfarbe%) or (aktfarbe%=altfarbe%) or (aktwort%=altwort%) or (akthgfarbe%=althgfarbe%) or (aktpwort%=aktpos%) or (aktpos%=altpos%) or (aktpwort%=altpwort%)
aktwort%=@rnd(anzworte%)+1
aktfarbe%=@rnd(anzfarben%)+1
aktpwort%=@rnd(anzpworte%)+1
aktpos%=@rnd(anzpos%)+1
akthgfarbe%=@rnd(anzfarben%)+1
endwhile
cls farbe%[akthgfarbe%]
textcolor @rgb(0,255,255),-1
usefont "Arial",16,0,0,0,0
drawtext 10,(@height(%HWnd)-26),"Modus 4: Farben, Positionen & Hintergrundfarben (M=Moduswechsel)",0
textcolor farbe%[aktfarbe%],-1
usefont "Arial",texthoehe%,0,1,0,0
drawtext posx%[aktpos%],posy%[aktpos%],wort$[aktwort%]+" "+pwort$[aktpwort%],6
altwort%=aktwort%
altfarbe%=aktfarbe%
altpos%=aktpos%
altpwort%=aktpwort%
althgfarbe%=akthgfarbe%
endif
waitinput
if @iskey(77) 'M
inc modus%
if modus%>anzmodi%
modus%=1
beep
sleep 150
beep
else
beep
endif
elseif (%umessage=$10) or @iskey(27)
ende%=1
endif
endwhile
ENDPROC 'FWI


'Hauptprogramm
windowstyle 1+2+4+8+16+512
window 0,0-%maxx,(%maxy-30)
windowtitle "Farb-Wort-/Ort-Wort-/Farb-Ort-Wort-Interferenz © by Jens-Arne Reumschüssel in 2017"
randomize
usermessages $10
@messagebox("Farb-/Ort-Wort-Interferenz\n\nEin beliebter Test aus der Hirnforschung: Ziel ist es, die Farben und (in den späteren mit \qM\q durchschaltbaren Modi) Orte der angezeigten Texte so schnell wie möglich zu benennen.\n\nDie Worte interferieren mit diesem Ziel. Wird z.B. das Wort \qgrün\q angezeigt, welches aber \
rot dargestellt ist, so ist \qRot!\q auszurufen. Ist das Wort \qoben\q unten dargestellt, ist \qUnten!\q die richtige Lösung.\n\nViel Spaß!","Farb-/Ort-Wort-Interferenz",64+4096)
fwi
usermessages -$10
end