Speed-Test

H.Brill

Habe mal (gerade wegen den Move("...ToList", ...) Funktionen einen Speedtest gemacht.

Code

Declare Handle btn1, btn2, btn3, ME
Declare Long zArray[], ende, start, stop
Declare String Datei
WindowTitle "Kleiner Speed - Test"
Window 600, 400
btn1 = Create("Button", %HWnd, "Dateien", 10, 10, 60, 25)
btn2 = Create("Button", %HWnd, "Arrays", 110, 10, 60, 25)
btn3 = Create("Button", %HWnd, "Ende", 520, 10, 60, 25)
ME   = Create("MultiEdit", %HWnd, "", 10, 60, 560, 270)
SendMessage(ME, $00CF, 1, 0) ' MultiEdit auf Read only
ende = 0
Datei = $ProgDir + "Testfile.txt"
SetSize zArray[], 20000
MAT zArray[]  < 1
InitFile()
WhileNot ende
 WaitInput
 If Clicked(btn1)
    ' Datei - Operationen
    start = &GetTickCount
    FileToList1()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Zeilen : \:stop; Millisekunden bei Move(FileToList,...)\n"
    start = &GetTickCount
    FileToList2()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Zeilen : \:stop; Millisekunden mit normalen Datei-Operationen\n\n"
 ElseIf Clicked(btn2)
    ' Array To List
    start = &GetTickCount
    ArrayToList1()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Arrayelementen : \:stop; Millisekunden bei Move(ArrToList,...)\n"
    start = &GetTickCount
    ArrayToList2()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Arrayelementen : \:stop; Millisekunden bei normalem Kopieren\n\n"
 ElseIf Clicked(btn3)
    ende = 1
 EndIf
EndWhile
End
Proc InitFile
ClearList
UseCursor 15
WhileLoop 1, 20000
 AddString(0, Str$(&LOOP) + "." + " Zeile")
EndWhile
Move("ListToFile", Datei)
UseCursor 0
EndProc
Proc FileToList1
ClearList
Move("FileToList", Datei)
EndProc
Proc FileToList2
Declare String zeile
Assign #1, Datei
Reset #1
ClearList
WhileNot Eof(#1)
 Input #1, zeile
 AddString(0, zeile)
EndWhile
Close #1
EndProc
Proc ArrayToList1
ClearList
Move("ArrToList", zArray[])
EndProc
Proc ArrayToList2
ClearList
WhileLoop 0, SizeOf(zArray[]) - 1
 AddString(0, Str$(zArray[&LOOP]))
EndWhile
EndProc

Alles anzeigen

Ist ja schon erstaunlich.

Werbepost

Hallo!

Wenn du gerade an deiner Website arbeitest oder dein aktuelles Hosting überdenkst: Wir betreiben mit NetzLiving eine Hosting-Plattform, die speziell auf Performance, Sicherheit und einfache Verwaltung ausgelegt ist.

✔️ Schnelle Ladezeiten (optimiert für WordPress, WoltLab & Co.)
✔️ Deutsche Server & DSGVO-konform
✔️ Persönlicher Support (kein 0815-Ticket-System)

Mehr erfahren

Volkmar

Ja, der Unterschied ist bemerkenswert. Sowas sollte man im Hinterkopf behalten, wenn es mal wieder ums Tempo geht

Gruß Volkmar

H.Brill

So, habe jetzt auch mal die MoveListProc einbezogen. Ist ja auch noch eine Möglichkeit.

Code

Declare Handle btn1, btn2, btn3, ME
Declare Long zArray[], ende, start, stop
Declare String Datei
WindowTitle "Kleiner Speed - Test"
Window 600, 400
btn1 = Create("Button", %HWnd, "Dateien", 10, 10, 60, 25)
btn2 = Create("Button", %HWnd, "Arrays", 110, 10, 60, 25)
btn3 = Create("Button", %HWnd, "Ende", 520, 10, 60, 25)
ME   = Create("MultiEdit", %HWnd, "", 10, 60, 560, 270)
SendMessage(ME, $00CF, 1, 0) ' MultiEdit auf Read only
ende = 0
Datei = $ProgDir + "Testfile.txt"
SetSize zArray[], 20000
MAT zArray[]  < 1
InitFile()
WhileNot ende
 WaitInput
 If Clicked(btn1)
    ' Datei - Operationen
    start = &GetTickCount
    FileToList1()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Zeilen : \:stop; Millisekunden bei Move(FileToList,...)\n"
    start = &GetTickCount
    FileToList2()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Zeilen : \:stop; Millisekunden mit normalen Datei-Operationen\n"
    Set("MoveListMode", 1)
    start = &GetTickCount
    FileToList1()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Zeilen : \:stop; Millisekunden mit MoveListProc\n"
    SetText ME, GetText$(ME) + MkStr$("-", 200) + "\n"
    Set("MoveListMode", 0)
 ElseIf Clicked(btn2)
    ' Array To List
    start = &GetTickCount
    ArrayToList1()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Arrayelementen : \:stop; Millisekunden bei Move(ArrToList,...)\n"
    start = &GetTickCount
    ArrayToList2()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Arrayelementen : \:stop; Millisekunden bei normalem Kopieren\n"
    Set("MoveListMode", 1)
    start = &GetTickCount
    ArrayToList1()
    stop = &GetTickCount - start
    SetText ME, GetText$(ME) + "Dauer bei 20.000 Arrayelementen : \:stop; Millisekunden mit MoveListProc\n"
    SetText ME, GetText$(ME) + MkStr$("-", 200) + "\n"
    Set("MoveListMode", 0)
 ElseIf Clicked(btn3)
    SendMessage(%HWnd, $0010, 1, 0)
 EndIf
 case %Key = 2 : ende = 1
EndWhile
End
Proc InitFile
ClearList
UseCursor 15
WhileLoop 1, 20000
 AddString(0, Str$(&LOOP) + "." + " Zeile")
EndWhile
Move("ListToFile", Datei)
UseCursor 0
EndProc
Proc FileToList1
ClearList
Move("FileToList", Datei)
EndProc
Proc FileToList2
Declare String zeile
Assign #1, Datei
Reset #1
ClearList
WhileNot Eof(#1)
 Input #1, zeile
 AddString(0, zeile)
EndWhile
Close #1
EndProc
Proc ArrayToList1
ClearList
Move("ArrToList", zArray[])
EndProc
Proc ArrayToList2
ClearList
WhileLoop 0, SizeOf(zArray[]) - 1
 AddString(0, Str$(zArray[&LOOP]))
EndWhile
EndProc
MoveListProc
Parameters String s, Int i
If Get("MoveListMode") = 1
  AddString(0, s) 
EndIf
EndProc

Alles anzeigen

Scheint, als wäre die MoveListProc etwas langsamer, als das normale Kopieren.

Testet mal, was bei euch so rauskommt.

Volkmar

Ja, MoveListProc dauert geringfügig länger.

Gruß Volkmar

H.Brill

Habe es jetzt auch compilert und als .exe ausgeführt.

Da ist das gleiche Ergebnis.

Danke fürs Testen.

Speed-Test

Jetzt mitmachen!

Ähnliche Themen

ard mediathek auf samsung tv

Smart tv Samsung

WLAN Geschwindigkeit Testen

Vodafone-Speedtest bringt Fehlermeldung