Interessant, wie du das machst.
Normalerweise werden LNK's aber anders ausgelesen.
'Definitionen
DEF MultiByteToWideChar(6) ! "Kernel32","MultiByteToWideChar"
DEF CoInitialize(1) ! "OLE32","CoInitialize"
DEF CoUnInitialize(0) ! "OLE32","CoUninitialize"
DEF CoCreateInstance(5) ! "OLE32","CoCreateInstance"
Def SHGetSpecialFolderLocation(3) ! "SHELL32", "SHGetSpecialFolderLocation"
Def SHGetPathFromIDList(2) ! "SHELL32", "SHGetPathFromIDListA"
Def CoTaskMemFree(1) ! "OLE32", "CoTaskMemFree"
Declare buffer#
'Konstanten
DEF &PShell_Release 8
DEF &PShell_GetPath 12
DEF &PShell_Resolve 76
DEF &PFile_Release 8
DEF &PFile_Save 24
DEF &PFile_Load 20
'globale Variablen
Declare CLSID_IShellLink#
Declare IID_IShellLink#
Declare IID_IPersistFile#
Declare FindData#
Proc GetLinkPath
PARAMETERS LNK$
Declare Command&,Buffer$,PFile&
Declare Pshell&
Declare WideFile$
Dim FindData#,320
Dim CLSID_IShellLink#,16
LONG CLSID_IShellLink#,0 = $00021401
Word CLSID_IShellLink#,4 = $0000,$0000
Byte CLSID_IShellLink#,8 = $C0,$00,$00,$00,$00,$00,$00,$46
'
Dim IID_IShellLink#,16
LONG IID_IShellLink#,0 = $000214EE
Word IID_IShellLink#,4 = $0000,$0000
Byte IID_IShellLink#,8 = $C0,$00,$00,$00,$00,$00,$00,$46
'
Dim IID_IPersistFile#,16
LONG IID_IPersistFile#,0 = $0000010b
Word IID_IPersistFile#,4 = $0000,$0000
Byte IID_IPersistFile#,8 = $C0,$00,$00,$00,$00,$00,$00,$46
'
CoInitialize(0)
CoCreateInstance(CLSID_IShellLink#,0,1,IID_IShellLink#,Addr(PShell&))
Command& = Long(Pshell&,0)
CALL(LONG(COMMAND&,0),PShell&,IID_IPersistFile#,Addr(PFile&))'Interface ermitteln
WideFile$ = Space$(Len(LNK$)*2)
MultiByteToWideChar(0,1,addr(LNK$),-1,addr(WideFile$),Len(WideFile$))'LNK-File umwandeln
Command& = Long(PFile&,0)
CALL(LONG(COMMAND&,&PFile_Load),PFile&,Addr(WideFile$),1)'LinkFile laden
Command& = Long(Pshell&,0)
CALL(LONG(COMMAND&,&PShell_Resolve),PShell&,0,$3)
Buffer$ = Space$(260)
CALL(LONG(COMMAND&,&PShell_GetPath),PShell&,ADDR(Buffer$),260,FindData#,$4)'(Shortname)Pfad in Buffer$
CALL(LONG(COMMAND&,&PShell_Release),PShell&)
Command& = Long(PFile&,0)
CALL(LONG(COMMAND&,&PFile_Release),PFile&)
CoUnInitialize()
Dispose CLSID_IShellLink#
Dispose IID_IShellLink#
Dispose IID_IPersistFile#
Dispose FindData#
Return Trim$(Buffer$)
EndProc
Proc GetSpecialFolder
PARAMETERS CSIDL&
Declare lpIdl&, Result$
Dim Buffer#, 255
If External("Shell32","SHGetSpecialFolderLocation",0,CSIDL&, Addr(lpIdl&)) = 0
If External("Shell32","SHGetPathFromIDListA",lpIdl&, Buffer#) <> 0
Result$ = String$(Buffer#, 0)
EndIf
EndIf
External("OLE32","CoTaskMemFree",lpIdl&)
Dispose Buffer#
Return Result$+"\\"
EndProc
Declare SL$,SSS$,DesktopPath$
Declare Counter&,Path$
CLS
Counter& = 1
ClearList
DesktopPath$ = GetSpecialFolder(0)'Pfad zum Desktop-Ordner
AddFiles DesktopPath$+"*.*"
SL$ = MoveListToStr$(";")
Repeat
SSS$ = SUBSTR$(SL$,Counter&,";")
Path$ = GetLinkPath(DesktopPath$+SSS$)
If path$ <> "":Print Path$:Endif
Counter& = Counter& + 1
Until SSS$ = ""
WaitInput
End
Alles anzeigen