Zitat von True29;959568naja is halt nix was man wirklich brauch
Aber ein netter Bildschirmschoner ![]()
Zitat von True29;959568naja is halt nix was man wirklich brauch
Aber ein netter Bildschirmschoner ![]()
Da habe ich mal was altes umgeschrieben
Webcams mit Überblendeffekt.
[Blockierte Grafik: http://s12.postimage.org/j1f6poh2h/Screen_08_03_2013_14_Uhr_53_46_Sek.jpg]
'ampsoft(Andreas Miethe)
'Webcams mit Überblendeffekten
Dim% 10000
Declare w1%,h1%,xx%,x1%,y1%
Var breite% = 640
Var hoehe% = 480
Var XPlus% = External("User32.dll","GetSystemMetrics",7)
Var YPlus% = External("User32.dll","GetSystemMetrics",8)
Var YCaption% = External("User32.dll","GetSystemMetrics",4)
WindowStyle 536
WINDOW breite%+(XPlus%*2)6,hoehe%+((YPlus%*2)+YCaption%)
CLS 0
Randomize
breite% = width(%hwnd)
hoehe% = height(%hwnd)
Var l1%=Create("List",0)
Var l2%=Create("List",0)
Var w% = breite%
Var h% = hoehe%
MCLS w%,h%
Var Pic& = 0
Var A&=1
Var E&=0
LC()
Settimer 15000
WhileNot E&
WaitInput
If %wmtimer:LC():EndIf
If %key=2:E&=1:EndIf
If %MouseKey = 2
CreateMenu
AppendMenu 100,"TimeOut 10 Sekunden"
AppendMenu 101,"Timeout 15 Sekunden"
AppendMenu 102,"Timeout 20 Sekunden"
AppendMenu 103,"Timeout 30 Sekunden"
AppendMenu 104,"Timeout 1 Minute"
Separator
AppendMenu 105,"Ende"
TrackMenu %MouseX,%Mousey
If MenuItem(100) : Killtimer:Settimer 10000:Endif
If MenuItem(101) : Killtimer:Settimer 15000:Endif
If MenuItem(102) : Killtimer:Settimer 20000:Endif
If MenuItem(103) : Killtimer:Settimer 30000:Endif
If MenuItem(104) : Killtimer:Settimer 60000:Endif
If MenuItem(105) : E& = 1::Endif
EndIf
EndWhile
Killtimer
External("Kernel32.dll","DeleteFileA",$TempDir+"~~~B.jpg")
Proc LC
External("Kernel32.dll","DeleteFileA",$TempDir+"~~~B.jpg")
If a& < 5
Var u$="http://www.bicos.de/webcam/webcam"+str$(A&)+".jpg"
WindowTitle "Bielefeld "+str$(A&)
ElseIf a& = 5
Var u$="http://www.berlin.de/webcams/_img/webcam/alex.jpg"
WindowTitle "Berlin"
ElseIf a& = 6
Var u$ = "http://www.opentopia.com/images/data/cams/14271/big.jpg"
WindowTitle "Washington"
ElseIf a& = 7
Var u$ = "http://129.171.33.49/jpg/image.jpg"
WindowTitle "Miami"
ElseIf a& = 8
Var u$ = "http://abclocal.go.com/three/kabc/webcam/web1-1.jpg"
WindowTitle "Long Beach LA"
ElseIf a& = 9
Var u$ = "http://www.esrl.noaa.gov/gmd/webdata/spo/webcam/medium.jpg"
WindowTitle "Südpol"
EndIf
Downloadfile(u$,$TempDir+"~~~B.jpg")
While %Loading
Sleep 1
EndWhile
If &BytesRead <> -1
Pic& =Create("hPic", -1, $TempDir+"~~~B.jpg")
If Pic& <> 0
StartPaint -1
DrawSizedPic Pic&,0,0-w%,h%;0
EndPaint
DeleteObject Pic&
Select a&
CaseOf 1,5
OSchnitt()
CaseOf 2,6
LSchnitt()
CaseOf 3,8
LRzeilen()
OTHERWISE
Pixel()
EndSelect
Else
cls 0
TextColor $00CCFF,-1
DrawText 250,230,"Bild momentan nicht ladbar"
EndIf
EndIf
Inc A&
If A&=10
A&=1
EndIf
EndProc
Proc Pixel
RECHNE(80)
xx%=0
WhileNot getcount(l1%)=0
xx%=rnd(getcount(l1%))
x1%=val(substr$(GetString$(l1%,xx%),1,","))
y1%=val(substr$(GetString$(l1%,xx%),2,","))
MCopyBmp X1%,Y1%-w1%,h1% > X1%,Y1%;0
DeleteString(l1%,xx%)
EndWhile
EndProc
Proc OSchnitt
Var z%=0
Var adder% = 0
WhileNot z%=30
WhileNot adder% > hoehe%
MCopyBmp 0,(z%+adder%)-w%,1 > 0,(z%+adder%),0;0
Inc adder%,30
EndWhile
adder% = 0
Inc z%
Sleep 1
EndWhile
EndProc
Proc LSchnitt
Var z%=0
Var adder% = 0
whileloop 0,40
whileloop 0,w%,40
MCopyBmp (z%+&loop),0-1,h% > (z%+&loop),0;0
EndWhile
Inc z%
Sleep 1
endwhile'
EndProc
Proc LRZeilen
Var z1%=w%
Var z%=0
WhileNot z%>w%
MCopyBmp z%,0-4,h% > z%,0;0
MCopyBmp z1%,0-4,h% > z1%,0;0
Sleep 1
Add z%,4
dec z1%,4
EndWhile
EndProc
Proc Rechne
PARAMETERS teiler%
w1% = w%\Teiler%
h1% = h%\Teiler%
Var zahl1%=0
Var zahl2%=0
Var a%=0
Var b%=Teiler%
xx%=0
While zahl1%<w%
List% a%=zahl1%
Inc a%
Add zahl1%,w1%
EndWhile
While zahl2%<h%
List% b%=zahl2%
Inc b%
Add zahl2%,h1%
EndWhile
Declare liste$
Clearlist
a%=0
b%=teiler%
WhileNot a%>teiler%-1
WhileNot xx%>teiler%-1
AddString str$(list%(a%))+","+str$(list%(b%))
Inc b%
Inc xx%
EndWhile
xx%=0
b%=teiler%
Inc a%
EndWhile
movelisttohandle(l1%)
movelisttohandle(l2%)
EndProc
Alles anzeigen
Zitat von jaschi;950535Hallo,
die Funktion mit copy und paste funktioniert anscheinend nicht richtig, da ja der String mit "val" umgewandelt wird und ab dem Komma alles "abgeschnitten" ist.
Ich habe den Code mal entsprechend abgeändert. Sollte jetzt korrekt funktionieren.
Zitat von _Joerg_;950471Coole Sache.
Die Prozedur kannst du sogar sparen Dank ClassOf(hdl&)
Danke, hatte ich schon wieder vergessen.
Ich hab's im Beispiel geändert.
Die Vorschläge von Frank und Thomas sind auch eingebaut. Danke dafür.
Zitat von Frabbing;950437Man merkt also, Subclassing ist fast unbegrenzt ausbaufähig.
Trotzdem immer dran denken: Innerhalb des XProfan-Subclassings so kurz wie nötig fassen...
Hat zwar jetzt nichts mit Subclassing zu tun ist eine nette Geschichte.
Ein Hinweistext direkt im EDIT ( funktioniert ab XP ).
[Blockierte Grafik: http://s9.postimage.org/wmq389bsr/20121230_194652.jpg]
'##########################
'benötigte Header-Dateien einbinden
'##########################
$H Windows.ph
$H Messages.ph
'##########################
'Fenster anlegen
'##########################
WindowStyle 536'DialogStil setzen
WindowTitle "Berechne"
WINDOW 365,250
CLS ~GetSysColor(~COLOR_BTNFACE)
Set("Decimals",4)
SetDialogFont ~GetStockObject(~DEFAULT_GUI_FONT)
'##########################
'Globale Variablen anlegen
'##########################
DEF &EM_SETCUEBANNER $1501
'##########################
'das Fenster aufbauen
'##########################
Create("Text",%hWnd,"Eingabe X1:",10, 8,120,20)
Create("Text",%hWnd,"Eingabe X2:",10,33,120,20)
Create("Text",%hWnd,"Eingabe Y1:",10,58,120,20)
Create("Text",%hWnd,"Eingabe Y2:",10,83,120,20)
Create("Text",%hWnd,"Eingangssignal:",10,108,120,20)
Create("Text",%hWnd,"Die Steigung beträgt:",10,168,200,20)
Create("Text",%hWnd,"Das Ausgangssignal beträgt:",10,193,200,20)
Var X1% = Create("Edit",%hWnd,"",150, 5,185,20)
Var X2% = Create("Edit",%hWnd,"",150,30,185,20)
SendMessage(X2%,&EM_SETCUEBANNER,1,WideString("ungleich NULL oder X1"))
Var Y1% = Create("Edit",%hWnd,"",150,55,185,20)
SendMessage(Y1%,&EM_SETCUEBANNER,1,WideString("darf nicht leer sein"))
Var Y2% = Create("Edit",%hWnd,"",150,80,185,20)
Var ES% = Create("Edit",%hWnd,"",150,105,185,20)
Var hB% = Create("Button",%hWnd,"&Berechnen",10,133,80,25)
Var hA% = Create("Button",%hWnd,"&Schließen",250,133,80,25)
Var hh% = Create("Button",%hWnd,"&Neues Fenster",150,133,80,25)
Var T1% = Create("Text",%hWnd,"",248,193,85,20)
Var T2% = Create("Text",%hWnd,"",248,168,85,20)
'##########################
'Subclassing für die Edits einschalten
'##########################
SubClass X1%, 1
SubClass X2%, 1
SubClass Y1%, 1
SubClass Y2%, 1
SubClass ES%, 1
SetFocus(X1%)
'##########################
'Hauptschleife
'##########################
While 1
WaitInput
Case %key = 2 : BREAK'Fenster soll geschlossen werden(ESC,ALT+F4,Schliessen-Kreuz,Systemmenu-Schliessen)
If Clicked(hb%)
If CheckValues()
Berechnen()
EndIf
ElseIf Clicked(ha%)
Break
ElseIf Clicked(hh%)
NeuesFenster()
EndIf
EndWhile
DestroyWindow(%hwnd)
End
Proc NeuesFenster
'Prozedur für das 2. Fenster
Var Kindfenster& = Create("Dialog",%hwnd,"Substrahieren",%winleft,%wintop,365,250)
Var Ende& = Create("Button",Kindfenster&,"Ende",10,10,120,24)
Var Edit& = Create("Edit",Kindfenster&,"",10,40,120,20)
Create("Text",KindFenster&,"minus",135, 42,30,20)
Var Edit1& = Create("Edit",Kindfenster&,"",170,40,120,20)
Var Rechne& = Create("Button",Kindfenster&,"Rechnen",10,100,120,24)
Var Ergebnis& = Create("Text",Kindfenster&,"",10,130,120,24)
SubClass Edit&,1'SubClassing einschalten
SubClass Edit1&,1'SubClassing einschalten
SetFocus(Edit&)
Var KindEnde& = 0
While KindEnde& = 0
WaitInput
Case %key = 2 : KindEnde& = 1
If Clicked(Ende&)
KindEnde& = 1
ElseIf Clicked(Rechne&)
Settext Ergebnis&,"Ergebnis :"+Format$("0.0000",val(translate$(GetText$(Edit&),",","."))-val(translate$(GetText$(Edit1&),",",".")))
EndIf
EndWhile
SubClass Edit&,0'SubClassing ausschalten
SubClass Edit1&,0'SubClassing ausschalten
DestroyWindow(KindFenster&)
EndProc
'##########################
'die benötigten Prozeduren
'##########################
Proc Berechnen
Var X1! = val(translate$(GetText$(X1%),",","."))
Var X2! = val(translate$(GetText$(X2%),",","."))
Var Y1! = val(translate$(GetText$(Y1%),",","."))
Var Y2! = val(translate$(GetText$(Y2%),",","."))
Var ES! = val(translate$(GetText$(ES%),",","."))
Var ST! = ((Y2!-Y1!)/(X2!-X1!))
Var AS!=(ES!*ST!)+Y1!
Settext T2%,Format$("0.0000",round(ST!,4))
SetText T1%,Format$("0.0000 %",round(AS!,4))
EndProc
Proc CheckValues
'##########################
'hier werden die zwei Edits überprüft die keine NULL erlauben
'##########################
If Val(Gettext$(X2%)) = 0
~Messagebox(0,"unkorrekte Eingabe in X2 - bitte prüfen","Fehler",16)
SetText X2%,""
SetFocus(X2%)
Return 0
ElseIf Val(Gettext$(Y1%)) = 0
~Messagebox(0,"unkorrekte Eingabe in Y1 - bitte prüfen","Fehler",16)
SetText Y1%,""
SetFocus(Y1%)
Return 0
ElseIf Val(Gettext$(X1%)) = Val(Gettext$(X2%))
~Messagebox(0,"gleiche Eingabe in X1 und X2 - bitte prüfen","Fehler",16)
SetText X1%,""
SetFocus(X1%)
Return 0
EndIf
Return 1
EndProc
Subclassproc
'##########################
'hier wird die Eingabe in die Edits überwacht
'nur Zahlen,Minus,Komma und Backspace werden erlaubt
'##########################
If Upper$(ClassOf(&swnd)) = "EDIT"'alle Edits werden gleich behandelt
If SubClassMessage(&swnd,~WM_CHAR)
Set("WinProc", 1)'weiterleiten
If (&swParam > 47) and (&swParam < 58) 'alle Zahlen bearbeiten
ElseIf (&swParam = 45) AND (SendMessage(&swnd,~EM_GETSEL,0,0)=0)'Minus nur am Anfang
ElseIf (&swParam= 44) AND (Instr(",",Gettext$(&swnd))=0)'Komma nur einmal
ElseIf &swParam = ~VK_BACK'Backspace
Else
Set("WinProc", 0)'sonst nicht weiterleiten
EndIf
ElseIf SubClassMessage(&swnd,~WM_PASTE)
Var a$ = GetClip$()
If Instr(".",a$) > 0'wenn Punkt vorhanden
a$ = translate$(Str$(Val(a$)),".",",")
Endif
ClearClip
If Val(a$) <> 0:PutClip a$:Endif
SetFocus(&swnd)
EndIf
EndIf
EndProc
Proc WideString
PARAMETERS S$ : Declare w# : Dim w#,(Len(s$)*2)+2 : StringW w#,0 = S$ : Return w#
EndProc
Alles anzeigen
Zitat von jaschi;950323Alles anzeigen
hab da noch ein paar Fragen.
Ich möchte mein Programm jetzt erweitern.
Wie funktioniert das mit dem subclassing?
Ich möchte im Hauptfenster (%hWnd) mehrere Buttons anlegen (für diverse andere Formeln),
die dann in das dazugehörige Unterfenster springt (%hxx).
Hierbei soll aber die Funktion der Eingabe wie in der subclassproc erhalten bleiben.
Wie aktiviere oder schalte ich jetzt die subclass für jedes weitere Fenster ein?
Wie definiere ich neue subclasses, da in den anderen Fenstern andere Variable gebraucht werden.
Ich hoffe, dass ich mich verständlich ausgedrückt habe.
Am einfachsten ist es dann die Subclass-Prozedur so zu gestalten, dass es für alle Edit-Controls gleich funktioniert.
Ich habe Dir das Beispiel mal dementsprechend angepasst.
Ebenso ist jetzt ein zweites Fenster vorhanden, das sich auf Knopfdruck öffnet.
Ich hoffe Du findest da durch.
#########################
'B'benötigte Header-Dateien einbinden
'##########################
$H Windows.ph
$H Messages.ph
'##########################
'Fenster anlegen
'##########################
WindowStyle 536'DialogStil setzen
WindowTitle "Berechne"
WINDOW 365,250
CLS ~GetSysColor(~COLOR_BTNFACE)
Set("Decimals",4)
SetDialogFont ~GetStockObject(~DEFAULT_GUI_FONT)
'##########################
'Globale Variablen anlegen
'##########################
'##########################
'das Fenster aufbauen
'##########################
Create("Text",%hWnd,"Eingabe X1:",10, 8,120,20)
Create("Text",%hWnd,"Eingabe X2 muss ungleich 0 sein:",10,33,300,20)
Create("Text",%hWnd,"Eingabe Y1:",10,58,120,20)
Create("Text",%hWnd,"Eingabe Y2:",10,83,120,20)
Create("Text",%hWnd,"Eingangssignal:",10,108,120,20)
Create("Text",%hWnd,"Die Steigung beträgt:",10,168,200,20)
Create("Text",%hWnd,"Das Ausgangssignal beträgt:",10,193,200,20)
Var X1% = Create("Edit",%hWnd,"",250, 5,85,24)
Var X2% = Create("Edit",%hWnd,"",250,30,85,24)
Var Y1% = Create("Edit",%hWnd,"",250,55,85,24)
Var Y2% = Create("Edit",%hWnd,"",250,80,85,24)
Var ES% = Create("Edit",%hWnd,"",250,105,85,24)
Var hB% = Create("Button",%hWnd,"&Berechnen",10,133,80,25)
Var hA% = Create("Button",%hWnd,"&Schließen",250,133,80,25)
Var hh% = Create("Button",%hWnd,"&Neues Fenster",150,133,80,25)
Var T1% = Create("Text",%hWnd,"",248,193,85,20)
Var T2% = Create("Text",%hWnd,"",248,168,85,20)
'##########################
'Subclassing für die Edits einschalten
'##########################
SubClass X1%, 1
SubClass X2%, 1
SubClass Y1%, 1
SubClass Y2%, 1
SubClass ES%, 1
SetFocus(X1%)
'##########################
'Hauptschleife
'##########################
While 1
WaitInput
Case %key = 2 : BREAK'Fenster soll geschlossen werden(ESC,ALT+F4,Schliessen-Kreuz,Systemmenu-Schliessen)
If Clicked(hb%)
If CheckValues()
Berechnen()
EndIf
ElseIf Clicked(ha%)
Break
ElseIf Clicked(hh%)
NeuesFenster()
EndIf
EndWhile
End
Proc NeuesFenster
'Prozedur für das 2. Fenster
Var Kindfenster& = Create("Dialog",%hwnd,"Substrahieren",%winleft,%wintop,320,240)
Var Ende& = Create("Button",Kindfenster&,"Ende",10,10,120,24)
Var Edit& = Create("Edit",Kindfenster&,"",10,40,120,24)
Create("Text",KindFenster&,"minus",135, 45,30,20)
Var Edit1& = Create("Edit",Kindfenster&,"",170,40,120,24)
Var Rechne& = Create("Button",Kindfenster&,"Rechnen",10,100,120,24)
var Ergebnis& = Create("Text",Kindfenster&,"",10,130,120,24)
SubClass Edit&,1'SubClassing einschalten
SubClass Edit1&,1'SubClassing einschalten
SetFocus(Edit&)
Var KindEnde& = 0
While KindEnde& = 0
WaitInput
Case %key = 2 : KindEnde& = 1
If Clicked(Ende&)
KindEnde& = 1
ElseIf Clicked(Rechne&)
Settext Ergebnis&,"Ergebnis :"+Format$("0.0000",val(translate$(GetText$(Edit&),",","."))-val(translate$(GetText$(Edit1&),",",".")))
EndIf
EndWhile
SubClass Edit&,0'SubClassing ausschalten
SubClass Edit1&,0'SubClassing ausschalten
DestroyWindow(KindFenster&)
EndProc
'##########################
'die benötigten Prozeduren
'##########################
Proc Berechnen
Var X1! = val(translate$(GetText$(X1%),",","."))
Var X2! = val(translate$(GetText$(X2%),",","."))
Var Y1! = val(translate$(GetText$(Y1%),",","."))
Var Y2! = val(translate$(GetText$(Y2%),",","."))
Var ES! = val(translate$(GetText$(ES%),",","."))
Var ST! = ((Y2!-Y1!)/(X2!-X1!))
Var AS!=(ES!*ST!)+Y1!
Settext T2%,Format$("0.0000",round(ST!,4))
SetText T1%,Format$("0.0000 %",round(AS!,4))
EndProc
Proc CheckValues
'##########################
'hier werden die zwei Edits überprüft die keine NULL erlauben
'##########################
If Val(Gettext$(X2%)) = 0
Messagebox("unkorrekte Eingabe in X2 - bitte prüfen","Fehler",16)
SetText X2%,""
SetFocus(X2%)
Return 0
ElseIf Val(Gettext$(Y1%)) = 0
Messagebox("unkorrekte Eingabe in Y1 - bitte prüfen","Fehler",16)
SetText Y1%,""
SetFocus(Y1%)
Return 0
ElseIf Val(Gettext$(X1%)) = Val(Gettext$(X2%))
Messagebox("gleiche Eingabe in X1 und X2 - bitte prüfen","Fehler",16)
SetText X1%,""
SetFocus(X1%)
Return 0
EndIf
Return 1
EndProc
Subclassproc
'##########################
'hier wird die Eingabe in die Edits überwacht
'nur Zahlen,Minus,Komma und Backspace werden erlaubt
'##########################
If GetWindowName(&swnd) = "EDIT"'alle Edits werden gleich behandelt
If SubClassMessage(&swnd,~WM_CHAR)
Set("WinProc", 1)'weiterleiten
If (&swParam > 47) and (&swParam < 58) 'alle Zahlen bearbeiten
ElseIf &swParam = 45'Minus
ElseIf &swParam = 44'Komma
ElseIf &swParam = ~VK_BACK'Backspace
Else
Set("WinProc", 0)'sonst nicht weiterleiten
EndIf
ElseIf SubClassMessage(&swnd,~WM_CONTEXTMENU)
SendMessage(&swnd,~WM_LBUTTONDOWN,0,0)
SendMessage(&swnd,~WM_LBUTTONUP,0,0)
Set("WinProc", 0)'nicht weiterleiten
EndIf
EndIf
EndProc
Proc GetWindowName
PARAMETERS Handle&
Var Name$ = Space$(256)
~GetClassname(Handle&,Addr(Name$),Sizeof(Name$))
Return Trim$(Upper$(Name$))
EndProc
Alles anzeigen
Zitat von GT43A;950115Ja Andreas da hast du vollkommen Recht!
Aber auch in deinem Beispiel ist es möglich irgendein Schmarren ein zu geben!;)
Stimmt ! Das kann man aber abfangen
Subclassproc
'##########################
'hier wird die Eingabe in die Edits überwacht
'nur Zahlen,Minus,Komma und Backspace werden erlaubt
'##########################
If (&swnd = X2%) or (&swnd = Y1%) or (&swnd = X1%) or (&swnd = Y2%) or (&swnd = ES%)
If SubClassMessage(&swnd,~wm_char)
Set("WinProc", 1)'weiterleiten
If (&swParam > 47) and (&swParam < 58) 'alle Zahlen bearbeiten
ElseIf &swParam = 45'Minus
ElseIf &swParam = 44'Komma
ElseIf &swParam = ~VK_BACK'Backspace
Else
Set("WinProc", 0)'sonst nicht weiterleiten
EndIf
'#################
'Rechte Maustast abfangen
'#################
Elseif SubClassMessage(&swnd,~WM_CONTEXTMENU)
SendMessage(&swnd,~WM_LBUTTONDOWN,0,0)
SendMessage(&swnd,~WM_LBUTTONUP,0,0)
Set("WinProc", 0)'sonst nicht weiterleiten
EndIf
EndIf
EndProc
Alles anzeigen
Zitat von jaschi;950033Hallo Andreas,
Jetzt habe ich nur noch ein Problem mit dem Programm und zwar bei gleicher Eingabe bei X1 und X2 kommt die Fehlermeldung "Division durch 0".
Mit der variablen er% habe ich die Anzahl der Eingaben im Feld X1 gezählt.
Hiermit wollte ich dann den Cursor im Feld X1 mit der gleichen Anzahl wieder zurückstellen, so dass die Eingabe im Feld X1 gelöscht ist.
Funktioniert aber auch nicht.
Du fragst das am besten in der Prozedur "Checkvalues" ab.
Füge dort
ElseIf Val(Gettext$(X1%)) = Val(Gettext$(X2%))
Messagebox("gleiche Eingabe in X1 und X2 - bitte prüfen","Fehler",16)
SetText X1%,""
SetFocus(X1%)
Return 0
ein.
Damit werden die beiden Eingabefelder verglichen.
Mit Settext X1%,"" wird das eingabefeld geleert, Du musst Dir also nichts merken.
Mit Setfocus wird der Cursor in das Eingabefeld gebracht.
Hallo jaschi,
ich habe Deinen Code mal so umgeschrieben wie Du ihn haben möchtest.
Du solltest unbedingt darauf achten, so wenig wie möglich in der Hauptschleife zu machen. Berechnungen irgendetwas prüfen usw. sollte in extra Prozeduren stattfinden.
Ich hoffe Du steigst da durch.
'##########################
'Benötigte Header-Dateien einbinden
'##########################
$H Windows.ph
$H Messages.ph
'##########################
'Fenster anlegen
'##########################
WindowStyle 536'DialogStil setzen
WindowTitle "Berechne"
WINDOW 365,250
CLS ~GetSysColor(~COLOR_BTNFACE)
Set("Decimals",4)
setdialogfont ~GetStockObject(~DEFAULT_GUI_FONT)
'##########################
'das Fenster aufbauen
'##########################
Create("Text",%hWnd,"Eingabe X1:",10, 8,120,20)
Create("Text",%hWnd,"Eingabe X2 muss ungleich 0 sein:",10,33,300,20)
Create("Text",%hWnd,"Eingabe Y1:",10,58,120,20)
Create("Text",%hWnd,"Eingabe Y2:",10,83,120,20)
Create("Text",%hWnd,"Eingangssignal:",10,108,120,20)
Create("Text",%hWnd,"Die Steigung beträgt:",10,168,200,20)
Create("Text",%hWnd,"Das Ausgangssignal beträgt:",10,193,200,20)
Var X1% = Create("Edit",%hWnd,"",250, 5,85,24)
Var X2% = Create("Edit",%hWnd,"",250,30,85,24)
Var Y1% = Create("Edit",%hWnd,"",250,55,85,24)
Var Y2% = Create("Edit",%hWnd,"",250,80,85,24)
Var ES% = Create("Edit",%hWnd,"",250,105,85,24)
Var hB% = Create("Button",%hWnd,"&Berechnen",10,133,80,25)
Var hA% = Create("Button",%hWnd,"&Schließen",250,133,80,25)
Var T1% = Create("Text",%hWnd,"",248,193,85,20)
Var T2% = Create("Text",%hWnd,"",248,168,85,20)
'##########################
'Subclassing für die Edits einschalten
'##########################
SubClass X1%, 1
SubClass X2%, 1
SubClass Y1%, 1
SubClass Y2%, 1
SubClass ES%, 1
SetFocus(X1%)
'##########################
'Hauptschleife
'##########################
While 1
WaitInput
Case %key = 2 : BREAK'Fenster soll geschlossen werden(ESC,ALT+F4,Schliessen-Kreuz,Systemmenu-Schliessen)
If Clicked(hb%)
If CheckValues()
Berechnen()
EndIf
ElseIf Clicked(ha%)
Break
EndIf
EndWhile
End
'##########################
'die benötigten Prozeduren
'##########################
Proc Berechnen
Var X1! = val(translate$(GetText$(X1%),",","."))
Var X2! = val(translate$(GetText$(X2%),",","."))
Var Y1! = val(translate$(GetText$(Y1%),",","."))
Var Y2! = val(translate$(GetText$(Y2%),",","."))
Var ES! = val(translate$(GetText$(ES%),",","."))
Var ST! = ((Y2!-Y1!)/(X2!-X1!))
Var AS!=(ES!*ST!)+Y1!
Var ST$ = str$(@round(ST!,4))
Var AS$ = str$(@round(AS!,4))
Settext T1%,AS$+" %"
Settext T2%,ST$
EndProc
Proc CheckValues
'##########################
'hier werden die zwei Edits überprüft die keine NULL erlauben
'##########################
If Val(Gettext$(X2%)) = 0
Messagebox("unkorrekte Eingabe - bitte prüfen","Feld1",0)
SetFocus(X2%)
Return 0
ElseIf Val(Gettext$(Y1%)) = 0
Messagebox("unkorrekte Eingabe - bitte prüfen","Feld2",0)
SetFocus(Y1%)
Return 0
EndIf
Return 1
EndProc
Subclassproc
'##########################
'hier wird die Eingabe in die Edits überwacht
'nur Zahlen,Minus,Komma und Backspace werden erlaubt
'##########################
If SubClassMessage(&swnd,~wm_char)
If (&swParam > 47) and (&swParam < 58) 'alle Zahlen bearbeiten
~DefWindowProc(&sWnd,%smessage, &swparam,&slparam)'Weiterleiten
ElseIf &swParam = 45'Minus
~DefWindowProc(&sWnd,%smessage,&swparam,&slparam)
ElseIf &swParam = 44'Komma
~DefWindowProc(&sWnd,%smessage,&swparam,&slparam)
ElseIf &swParam = ~VK_BACK'Backspace
~DefWindowProc(&sWnd,%smessage,&swparam,&slparam)
Else
Set("WinProc", 0)'sonst nicht weiterleiten
EndIf
EndIf
EndProc
Alles anzeigen
Zitat von GT43A;949879Hallo
ohne API und DLL!;)
Naja, ohne API ![]()
Und so kannst Du trotzdem eine NULL eingeben. Erst eine 1 dann nach links und die Null.
Besser gleich per Subclassing.
$H Windows.ph
$H Messages.ph
Declare Edit1&,Edit2&
wINDOWSTYLE 543'DialogStil setzen, dann kann per TAB der Focus gewechselt werden
CLS
Edit1& = @Create("Edit",%Hwnd,"",60,60,200,21)
~SetWindowLong(Edit1&,~GWL_STYLE, ~GetWindowLong(Edit1&,~GWL_STYLE) | ~ES_NUMBER)'nur Zahlen erlauben
SendMessage(Edit1&,~EM_LIMITTEXT,3,0)'Nur 3 Zeichen erlauben
Edit2& = @Create("Edit",%Hwnd,"",60,90,200,21)
~SetWindowLong(Edit2&,~GWL_STYLE, ~GetWindowLong(Edit2&,~GWL_STYLE) | ~ES_NUMBER)'nur Zahlen erlauben
SendMessage(Edit2&,~EM_LIMITTEXT,3,0)'Nur 3 Zeichen erlauben
SubClass Edit1&, 1 'SubClassing für Edit1 einschalten
SubClass Edit2&, 1 'SubClassing für Edit2 einschalten
@SetFocus(Edit1&)
While 1
WaitInput
Case %key = 2 : BREAK'Fenster soll geschlossen werden(ESC,ALT+F4,Schliessen-Kreuz,Systemmenu-Schliessen)
EndWhile
End
Subclassproc
If SubClassMessage(&swnd,~wm_keydown)
If classname(&swnd) = "EDIT"'nur reagieren wenn der Klassenname EDIT ist
If (&swparam = 48) or (&swparam = 96)'Null auf Tastatur oder Zahlenfeld
Sendkey(Edit1&,~VK_BACK)'Cursor um ein Zeichen zurück
EndIf
EndIf
EndIf
EndProc
Proc Classname
PARAMETERS Handle&
Var Classname$ = Space$(256)
~GetClassname(Handle&,Addr(Classname$),256)
Return Upper$(Trim$(Classname$))
EndProc
Alles anzeigen
Zitat von Frabbing;949271Fehlt die dwmapi.dll... also erst ab Vista?
Sieht so aus.
Du kannst aber die paar Zeilen ( 47 - 51 und 168-170) einfach mal auskommentieren, sollte dann funtionieren.
Die PH-Files sind jetzt im ZIP-File enthalten, also bitte eventuell neu laden.
Ich habe XP leider nur in einer virtuellen Maschine, und damit ( virtuelle Maschine ) funktioniert das definitiv nicht.
Da habe ich noch etwas schönes, passt auch gut in diese Zeit.
Das Programm ändert der Bildschirm-Hintergrund und zwar ganz besonders, hat nicht jeder. ![]()
http://www.ampsoft.eu/desktopvideo.zip
Natürlich als Quelltext !
Hallo Frank,
ich hab's mal getestet.
Abhilfe schafft das hier :
http://www.google.de/url?sa=t&rct=j…9,d.Yms&cad=rja
Nach der Installation lief bei mir alles wie gewünscht.
Zitat von True29;948857hab den Code nun auch getestet.
Bei mir spielt er die Videos ab AVI und MP4 jedoch sehe ich sie erst wenn ich den Rahmen von Windows bewege.
Ein "REPAINT" sollte da helfen, einfach vor der Hautpschleife ausführen
Zitat von Frabbing;948856Ich vermute, du hast dazu diesen Code von PureBasic nach XProfan übersetzt?
Nein, war ein Delphi-Code.
Bei mir läuft das einwandfrei.
mag schon sein sein, dass das mit den installierten Codecs zusammenhängt.
Hier ein Beispiel für DirectShow mit Xprofan ( ohne zusätzliche Dll ), reiner Xprofan-Quelltext.
Zitat von ts-soft;948582Da sollte man vielleicht den Andreas M. mal interviewen, ich denke nicht, das
dies auf seinen Mist gewachsen ist.
Ich denke mal nicht ![]()
Die WMI.Inc ist inzwischen auch schon korrigiert.
Für WMI-Abfragen habe ich mir aber schon eine Dll geschrieben, das vereinfacht Einiges.
https://www.paules-pc-forum.de/forum/dlls-inc…095-ampwmi.html
Beispiel :
$H Windows.ph
ImportDll("AMP_WMI.DLL","")
WINDOW 800,600
WindowTitle "Codec-Files"
CLS
'Result$ nimmt alle Werte in einem STRING auf
Var Result$ = String$(WMIResult1("SELECT FileName,Manufacturer from Win32_CodecFile","root\CIMV2","","",""),0)
'A$[] nimmt Einzelstrings in ein Array auf
Declare A$[]
'B$[] nimmt Eintelstrings von A$[] in ein Array auf
Declare B$[]
'Gibt die Anzahl der Arrays zurück
Declare Numbers&
A$[] = Explode(Result$,chr$(10)+chr$(13))
Numbers& = (A$[0])
Declare Results$[Numbers&]
WhileLoop 0, SizeOf(A$[]) - 1
If Left$(A$[&loop],8) = "FileName"
B$[] = Explode(A$[&loop],";")
Whileloop 1,Numbers&
Results$[&Loop]= B$[&loop]
EndWhile
ElseIf Left$(A$[&loop],12) = "Manufacturer"
B$[] = Explode(A$[&loop],";")
Whileloop 1,Numbers&
Results$[&Loop]= Results$[&Loop]+" -> "+B$[&loop]
EndWhile
EndIf
EndWhile
'Ausgabe
whileloop 1,Numbers&
Print Results$[&loop]
EndWhile
WaitInput
Alles anzeigen
Hallo Johannes,
dann lass doch alles im Speicher passieren, geht durchaus.
Ups. habe gerade den Beitrag von Thomas gelesen. Link entfernt !
Zitat von True29;946830danke für die Lösung , später mal testen
wie kommst du nun auf eine () klammer statt eine [] ?
Mfg
So steht's halt in der Hilfe:-)
oder richtig anwenden.
@Set("RegEx", 1)
Declare inhalt%[15],inhalt$
cls
inhalt%[1]=5
inhalt%[4]=4
inhalt%[7]=11
inhalt%[10]=12
inhalt%[13]=8
inhalt$ = @Str$(inhalt%[1])+","+@Str$(inhalt%[4])+","+@Str$(inhalt%[7])+","+@Str$(inhalt%[10])+","+@Str$(inhalt%[13])
var suchmuster$="(11|12)"
inhalt$ = Translate$(inhalt$,suchmuster$,"NULL")'alle gefundenen durch NULL ersetzen
print inhalt$
waitinput
Alles anzeigen