Heya, hier ein Spaßexperiment. Und Wissensquiz: Wie heißt dieses Stück?
Getestet unter FreeProfan32, XProfan 12.1 und Windows 7. Compiliert besser! Ich weiß leider nicht, wie es unter 3 Ghz läuft. Wenn es mal ruckelt, geht in ein anderes Fenster (Graphen werden solange nicht neugezeichnet). Unter FreeProfan64 funktioniert es irgendwie nicht (waveOutPrepareHeader gibt MMSYSERR_INVALPARAM zurück, sodass alles stumm ist).
def %voices 6
declare p%,a%,t&,x%,y%,f%,m%[%voices],c%[9],Fade%,Bass%,Hook%,Drum%,NoMorse%,Arp%
def CreatePen(3) !"GDI32","CreatePen"
def CreateSolidBrush(1) !"GDI32","CreateSolidBrush"
def SelectObject(2) !"GDI32","SelectObject"
c%[0]=CreatePen(0,0,$33ff99):c%[5]=CreateSolidBrush($33ff99)
c%[1]=CreatePen(0,0,$33ff33):c%[6]=CreateSolidBrush($33ff33)
c%[2]=CreatePen(0,0,$339966):c%[7]=CreateSolidBrush($339966)
c%[3]=CreatePen(0,0,$335533):c%[8]=CreateSolidBrush($335533)
c%[4]=CreatePen(0,0,$333333):c%[9]=CreateSolidBrush($333333)
usermessages 16
windowtitle "Tasten 1-6 = Stummschaltung"
windowstyle $1A
window 800,600
case $profver>="11":startpaint %hdc
proc GenWave
parameters v%
x%=&gettickcount-t&[v%]
select i%[v%]
caseof 0 ' stumm
p%= 0
a%= 0
caseof 1 ' Bass
p%= 55+x%\9
a%= 60-x%\2
caseof 2 ' Morse
p%= 80
a%= 30
caseof 3 ' Hook
p%= 16+x%\9
a%= 63-x%\11:case a%<24:a%=24
caseof 4 ' Melodie
p%=if(x%<500,110-x%\7,20+x%\30)
a%=80-x%\7
' Sustain
case not(Hook%) and (a%<20):a%=20
' Tremolo schnell
y%=x% mod 105:case y%>=56:y%=112-y%
a%=a%+y%*if(x%<500,3,2)\7
' Tremolo langsam
y%=x% mod 900:case y%>=480:y%=960-y%
a%=a%+y%\20
' Release
case a%<0:a%=0
caseof 5 ' Piano
p%=140+x%\50
a%= 20-x%\60:case a%<10:a%=10
caseof 6 ' Chor
p%= 50+x% mod 150:case p%>=125:p%=250-p%
a%= 15
caseof 7 ' Xylophon
p%=128
a%= 30-x%\2:case a%<0:a%=0
caseof 8 ' Becken
p%= 0
a%= 64-x%\9:case a%<0:a%=0
caseof 9 ' Trommel
p%=128
a%=127-x%:case a%<0:a%=0
endselect
p%=p% & 255
a%=a%*f%\256
x%=w#+v%*306
y%=m%[v%]
if y% & 2
FillMemory(x% ,256 ,128 )
elseif i%[v%]<8
FillMemory(x% , p%,128-a%)
FillMemory(x%+p%,256-p%,128+a%)
else
dec x%,w#
whileloop x%,x%+p%- 1:byte w#,&loop=128-rnd(a%):endwhile
whileloop x%+p%,x%+255:byte w#,&loop=128+rnd(a%):endwhile
endif
casenot getactivewindow()=%hwnd:return
case (y% & 1)=iskey(49+v%):m%[v%]=(y%+1) & 3
x%=(v% mod 3)*260
y%=v%\3*260
inc p%,x%
SelectObject(%hdc,c%[4])
SelectObject(%hdc,c%[9])
if i%[v%]<8
rectangle x%,y% -x%+256,y%+128-a%:inc y%,128
rectangle p%,y% -x%+256,y% -a%
rectangle x%,y% -p% ,y% +a%
rectangle x%,y%+128-x%+256,y% +a%
SelectObject(%hdc,c%[m%[v%]])
SelectObject(%hdc,c%[m%[v%]+5])
rectangle x%,y% -p% ,y% -a%
rectangle p%,y% -x%+256,y% +a%
else
rectangle x%,y%-x%+256,y%+256:inc y%,128
SelectObject(%hdc,c%[m%[v%]])
whileloop x%,p%- 1:line &loop,y%-&loop,y%-rnd(a%):endwhile
whileloop p%,x%+255:line &loop,y%-&loop,y%+rnd(a%):endwhile
endif
endproc
$I SYNTH.INC
proc Akkord
case %umessage=16:return
parameters i%,1%,2%,3%
TonEin 1,i%,1%
TonEin 2,i%,2%
TonEin 3,i%,3%
endproc
proc Takt
whileloop 0,31
case %umessage=16:break
TonEin 0,1,Bass%+6*(&loop & 2)
if Drum%
casenot &loop:TonEin Drum%,8,20
casenot ((&loop-9) & 24) or (&loop=13) or (Bass%=33):TonEin Drum%,9,80-&loop*4
endif
ifnot NoMorse%
inc f%,Fade%
if not(&loop & 9) or ((&loop & 15)=3) or ((&loop & 15)=12)
TonEin 5,2,74-(Bass%=33) and (&loop=28)
elseif (&loop+10) & 12
TonEin 5,0,1
endif
else
casenot &loop & 3:TonEin 5,4,&(4+&loop\4)
endif
if Hook%
case ((Bass%=38) and (&loop=16)) or (&loop=20) or ((&loop & 27)=26):Akkord 0, 1, 1, 1
case (Bass%=38) and (&loop= 2) :Akkord 3,62,65,69
case (Bass%=38) and ((&loop=18) or (&loop=28)) :Akkord 3,62,67,71
case (Bass%=38) and (&loop=24) :Akkord 3,62,67,72
case (Bass%=33) and ((&loop= 2) or (&loop=24)) :Akkord 3,57,62,67
case (Bass%=33) and (&loop=28) :Akkord 3,57,61,67
endif
case Arp%:TonEin 4,7,&(12+&loop mod 3)
t&=t&+120
case abs(&gettickcount-t&)>300:t&=&gettickcount
getmessage
while &gettickcount<t&
whileloop 0,%voices-1
GenWave &loop
endwhile
endwhile
endwhile
endproc
proc Melodie
Hook%=0:Bass%=38:Takt 0,0,0,69, 0, 0, 0, 0,77,76,74,81,77,74
Takt 0,0,0,69, 0, 0, 0, 0,62,64,65,74,81,77
Akkord 5,60,64,67:Takt 0,0,0,64, 0, 0, 0, 0,60,62,64,79,76,72
Akkord 5,57,62,64:Takt 0,0,0,62, 0,57, 0,50,62,69,79,81,77,74
Takt 0,0,0,76, 0, 0, 0, 0,77,76,74,81,77,74
Takt 0,0,0,69, 0, 0, 0, 0,62,64,65,74,81,77
Akkord 5,60,64,67:Takt 0,0,0,64, 0, 0, 0, 0,60,62,64,79,76,72
Akkord 5,57,62,64:Takt 0,0,0,62, 0,57, 0,50, 0, 0, 0,81,77,74
Akkord 6,62,67,71:Takt 0,0,0,74, 0, 0, 0, 0, 0,74,76,83,79,74
Akkord 6,70,74,77:Takt 0,0,0,77, 0, 0, 0, 0, 0, 0,77,86,81,77
Akkord 6,72,76,79:Takt 0,0,0,79, 0, 0, 0, 0,77,76,74,86,81,77
Bass%=33:Akkord 6,69,73,76:Takt 0,0,0,76, 0, 0, 0, 0,79,77,76,86,81,77
casenot %umessage=16:TonEin 5,4,74
endproc
proc Hook
Hook%=1:Bass%=38:Takt 0,0,0, 0, 0, 0, 0, 0, 0, 0, 0,81,77,74
Takt 0,0,0, 0, 0, 0, 0, 0, 0, 0, 0,81,77,74
Takt 0,0,0, 0, 0, 0, 0, 0, 0, 0, 0,81,77,74
Bass%=33:Takt 0,0,0, 0, 0, 0, 0, 0, 0, 0, 0,86,81,77
endproc
settimer 0
whilenot %umessage=16
clear Hook%,Drum%,Arp%
Bass%=38:Fade%=2:Takt:Takt:Takt:Takt
Fade%=0:Hook
Drum%=4:Hook
NoMorse%=1:Drum%=0:Melodie
Drum%=4:Hook:Hook
Arp%=1:Drum%=0:Melodie
Arp%=0:Drum%=4:Hook
Arp%=1:Drum%=5:Hook:Takt 0,0,0,0
NoMorse%=0:Drum%=1:Hook
Fade%=-1:Hook:Hook
endwhile
killtimer
Fin
whileloop 0,9:deleteobject c%[&loop]:endwhile
case $profver>="11":endpaint
Alles anzeigen