Vielleicht hilft Dieters code das eine oder andere Problem zu lösen.
Code
'Der Code ist frei und ohne Einschränkungen nutzbar.
'Autor: Dieter Zornow
Def SetSysColor(1) !"USER32","GetSysColor"
Def ExtractIconEx(5) !"SHELL32","ExtractIconExA"
Def HiWord(1) Div&(&(1),$10000)
Def LoWord(1) And(&(1),$FFFF)
proc Setstatuspos
parameters hndl&
sendmessage(hndl&,5,0,0)
endproc
Proc GetNumbersOfParts 'Hier könnte man noch die Koordinaten abfragen
parameters hndl&
Declare numbers&
numbers& = sendmessage(hndl&,1030,0,0)
Return numbers&
endproc
Proc GetStatusRect
parameters hndl&,part&
Declare rect#,rect$
Dim rect#,16
sendmessage(hndl&,1034,part&,rect#)
Rect$ = str$(Long(rect#,0)) + "|"
Rect$ = Rect$ + str$(Long(rect#,4)) + "|"
Rect$ = Rect$ + str$(Long(rect#,8)) + "|"
Rect$ = Rect$ + str$(Long(rect#,12))
Dispose rect#
Return rect$
endproc
Proc GetStatusTextlenght
parameters hndl&,part&
Declare length&,type&
length& = sendmessage(hndl&,1027,part&,0)
type& = HiWord(length&)
length& = LoWord(length&)
return length&
endproc
Proc SetStatusTip 'Der Tip erscheint nur, wenn das Feld Text abschneidet oder nur ein Icon enthält
parameters hndl&,part&,text$
Declare tiptext$,buf#
tiptext$ = text$
if tiptext$ <> ""
sendmessage(hndl&,$410,part&,Addr(tiptext$))
else
Dim buf#,512
sendmessage(hndl&,1026,part&,buf#)
tiptext$ = string$(buf#,0)
Dispose buf#
sendmessage(hndl&,$410,part&,Addr(tiptext$))
endif
endproc
Proc SetStatusIcon
Parameters hndl&,part&,source$,Index&,size$
Declare IcHndl&,iar#
Dim iar#,4
if Upper$(size$) = "SMALL"
ExtractIconEx(addr(source$),index&,0,iar#,1) ' small Icons
elseif Upper$(size$) = "LARGE"
ExtractIconEx(addr(source$),index&,iar#,0,1) ' large Icons
sendmessage(hndl&,1032,34,0) 'mindesthöhe der Statusbar
sendmessage(hndl&,5,0,0) 'WM_SIZE senden zum Neuzeichnen
endif
IcHndl& = Long(iar#,0)
Dispose iar#
sendmessage(hndl&,1039,part&,IcHndl&)
return IcHndl&
endproc
proc DelStatusIcon
parameters Hndl&,part&
sendmessage(hndl&,1039,part&,0)
endproc
proc GetStatusIconHndl
parameters hndl&,part&
Declare Iconhndl&
Iconhndl& = sendmessage(hndl&,1044,part&,0)
Return Iconhndl&
endproc
Proc SetStatusHeight
Parameters hndl&,height&
sendmessage(hndl&,1032,height&,0) 'mindesthöhe der Statusbar
sendmessage(hndl&,5,0,0) 'WM_SIZE senden zum Neuzeichnen
endproc
Proc SetStatusText
Parameters style$,hndl&,part&,text$
declare fieldtext$
fieldtext$ = text$
if Upper$(Style$) = "RISEN"
sendmessage(hndl&,$401,part& | $0200,Addr(fieldtext$))
elseif Upper$(Style$) = "SUNKEN"
sendmessage(hndl&,$401,part&,Addr(fieldtext$))
sendmessage(hndl&,5,0,0) 'WM_SIZE senden zum Neuzeichnen
endif
endproc
Proc SetstatusParts
parameters hndl&,amount&,size$
decimals 0
Declare arr#,counter%,adr%
case amount& = 0:Return
Dim arr#,amount& * 4
counter% = 1
adr% = 0
whilenot counter% > amount&
long arr#,adr% = val(@SubStr$(Size$,counter%,","))
inc counter%
adr% = adr% + 4
endwhile
sendmessage(hndl&,1028,amount&,arr#)
Dispose arr#
decimals 6
endproc
Proc Setstatuscolor
parameters hndl&,Bcolor&
Declare oldcolor&
oldcolor& = sendmessage(hndl&,8193,0,Bcolor&)
sendmessage(hndl&,5,0,0) 'WM_SIZE senden zum Neuzeichnen
return oldcolor&
endproc
Proc GetStatusText
parameters hndl&,part&
Declare buf#,text$
Dim buf#,512
sendmessage(hndl&,1026,part&,buf#)
text$ = string$(buf#,0)
Dispose buf#
return text$
endproc
Proc CreateStatusbarEx
parameters WHnd&,ID&,where$,parts&,size$,Bcolor&
Declare sthndl&, para&
para& = %pcount
if Upper$(where$) = "BOTTOM"
sthndl& = Control("msctls_statusbar32","",$54000100 | $0800,0,0,0,0,WHnd&,id&,%hinstance,$0) 'unten
elseif Upper$(where$) = "TOP"
sthndl& = Control("msctls_statusbar32","",$54000101 | $0800,0,0,0,0,WHnd&,id&,%hinstance,$0) 'oben
endif
if para& = 6 'nur wenn Farbe übergeben wird im 4. Parameter
sendmessage(sthndl&,8193,0,Bcolor&)
endif
If parts& <> 0
SetstatusParts sthndl&,parts&,size$
endif
Return sthndl&
endproc
'Beispiel
cls
Declare status&,oldCol&
CreateStatusbarEx %Hwnd,1,"BOTTOM",4,"100,200,300,-1",RGB(255,53,96) 'mit Farbe beim Erzeugen, optional
status& = @&(0)
SetStatusText "RISEN",status&,0,"Dieter, das ist mein Vorname"
SetStatusText "SUNKEN",status&,1,"Zornow, das ist mein Nachname"
SetStatusIcon status&,2,"shell32.dll",60,"large"
SetStatusTip status&,0,""
SetStatusTip status&,1,""
SetStatusTip status&,2,"Ein Icon aus der shell32.dll"
GetStatusText status&,0
print @$(0)
GetStatusText status&,1
print @$(0)
GetStatusIconHndl status&,2
print "Iconhandle: ",@&(0)
GetStatusTextlenght status&,0
print "Textlänge in Feld 1: (Index 0)=",@&(0),"Zeichen"
GetStatusRect status&,0
Print
Print "Größe des 1. Feldes"
print "X:",Val(@SubStr$(@$(0),1,"|"))
print "Y:",Val(@SubStr$(@$(0),2,"|"))
print "X1:",Val(@SubStr$(@$(0),3,"|"))
print "Y2:",Val(@SubStr$(@$(0),4,"|"))
GetNumbersOfParts status&
Print
print "Anzahl Felder: ", @&(0)
waitinput 'Ein Tooltipereignis verlässt Waitinput in neuen Profanversionen
setStatusHeight status&,20 '= default value for W9x
DelStatusIcon status&,2
SetStatusIcon status&,2,"shell32.dll",60,"small"
Setstatuscolor status&,RGB(255,0,255)
oldcol& = @&(0)
while 1
getmessage
Setstatuspos status&
wend
end
'SB_SETICON = 1039 or $40F sendmessage(hndl&,1039,part&,IconHndl&) 'iconhndl = 0 löschen
'SB_SETTEXT = 1025 or $401 sendmessage(hndl&,1025,part&,Addr(text$))
'SB_SETTIPTEXT = 1040 or $410 sendmessage(hndl&,1040,part&,Addr(text$))
'SB_GETTEXT = 1026 or $402 sendmessage(Statbar&,1026,part&,buf#)
'SB_GETTEXTLENGTH = 1027 or $403 length& = sendmessage(Statbar&,1027,part&,0) lowword ist length, highword = type
'SB_GETTIPTEXT = 1042 or $412 sendmessage(Statbar&,1042,bufsize&,buf#)
'SB_SETPARTS = 1028 or $404 sendmessage(Statbar&,1028,Anzpart&,array_widths) last should be -1
'SB_GETPARTS = 1030 or $406 anzahl& = sendmessage(Statbar&,1030,part&,array or 0)
'SB_GETBORDERS = 1031 or $407 sendmessage(Statbar&,1031,0,array with 3 elements)
'SB_SETMINHEIGHT = 1032 or $408 sendmessage(Statbar&,1032,pixel&,0)
'SB_SIMPLE = 1033 or $409 sendmessage(Statbar&,1033,simple&,0) simple = 1 or 0
'SB_GETRECT = 1034 or $40A sendmessage(Statbar&,1034,part&,rect#)
'SB_ISSIMPLE = 1038 or $40E simple& = sendmessage(Statbar&,1034,0,0) non simple = 0
'SB_GETICON = 1044 or $414 Iconhndl& = sendmessage(Statbar&,1044,part&,0)
'SB_SETBKCOLOR = 8193 or $2001 / oldcolor& = sendmessage(Statbar&,8193,0,COLORREF)
'Styles
'SBT_OWNERDRAW = $1000;
'SBT_NOBORDERS = $0100;
'SBT_POPOUT = $0200;
'SBT_RTLREADING = $0400; 'andere Textrichtung
'SBT_TOOLTIPS = $0800;
Alles anzeigen
Gruß Thomas
[Blockierte Grafik: