Ich hatte vor einiger Zeit ja mal berichtet, dass meine XProfan-Programme auf meiner neuen CPU (Intel i7-14700K) viel langsamer sind als auf meiner alten (Intel i7-7700K). Ich habe jetzt endlich, endlich herausgefunden, warum das so ist und was man dagegen tun kann: Die neue CPU hat P- und E-Cores. Ich habe bisher immer verzweifelt versucht, meine XProfan-Programme irgendwie an die P-Cores zu binden, weil ich befürchtet hatte, dass Windows sie heimlich auf einen E-Core verschiebt. Abe das genaue Gegenteil ist der Fall! Man muss sie an einen E-Core binden, dann läuft alles superschnell. Offenbar kommen die modernen P-Cores bei der Branch-Prediction beim XProfan-Interpreter durcheinander und verplempern dabei sehr viel Zeit. Der Interpreter muss ja bei jedem Opcode eine riesige Schleife durchlaufen, um herauszufinden, um welchen Befehl es sich handelt und dann entsprechend zu verzweigen (Befehl=print? --> nein --> Befehl=if? --> nein --> Befehl=...). Die E-Cores kommen damit viel besser klar.
Dazu muss man die ProcessAffinityMask setzen (API-Befehl SetProcessAffinityMask). Dabei ist mir noch etwas aufgefallen: Alle XProfan-Programme haben standardmäßig eine ProcessAffinitiyMask von 1, was bedeutet, dass sie hart an den logischen Kern 1 (erster Thread des ersten Prozessorkerns) gebunden sind. Sie dürfen von Windows also auf keinen anderen Kern verschoben werden. Das war ganz, ganz früher mal sinnvoll, weil bei den ersten CoreDuo-Prozessoren z.B. Timing-Fehler zwischen den einzelnen Kernen auftauchen konnten. Das ist aber schon lange Geschichte. Es ist also wohl sinnvoll, bei jedem XProfan-Programm am Anfang alle logischen Kerne freizugeben:
Declare OrigAffinityMask&,SystemAffinityMask&
@External("kernel32.dll","GetProcessAffinityMask",@External("kernel32.dll","GetCurrentProcess"),@Addr(OrigAffinityMask&),@Addr(SystemAffinityMask&)) 'OrigAffinityMask& ist für XProfan-Programme offenbar immer 1 (logischer Kern 1=Thread 0 von Core 0)!!! Die SystemAffinityMask& enthält hingegen alle Cores mit allen ihren Threads.
@External("kernel32.dll","SetProcessAffinityMask",@External("kernel32.dll","GetCurrentProcess"),SystemAffinityMask&)
Das ist insbesondere dann wichtig, wenn man mit WinExec etc. andere Programme startet. Die erben nämlich die ProcessAffinityMask des Hauptprogramms, sodass die dann auch alle auf dem logischen Kern 1 laufen. Das will man ja bestimmt nicht so haben, schon gar nicht, wenn die mit mehreren Threads arbeiten.
Hier noch ein Code-Beispiel, das etwas flexibler ist (braucht JRPC3 und PureBasic, weil dort eine pbPROC verwendet wird):
STRUCT S_CpuCores=AnzPhysicalCores&,AnzThreads&,AnzPhysicalPCores&,AnzPhysicalECores&,AnzLogicalPCores&,AnzLogicalECores&,aCoreTypeArray&,aPCoreLogicalNumsString&,aECoreLogicalNumsString&
declare _OrigAffinityMask&,_SystemAffinityMask&
PBGLOBAL
Structure S_SYSTEM_LOGICAL_PROCESSOR_INFORMATION_EX
Relationship.l
Size.l
Flags.b
EfficiencyClass.b
Array Reserved.b(20)
GroupCount.w
EndStructure 'S_SYSTEM_LOGICAL_PROCESSOR_INFORMATION_EX
Structure S_CpuCores
AnzPhysicalCores.l '1-basiert (phyische Kerne)
AnzThreads.l '1-basiert
AnzPhysicalPCores.l '1-basiert (phyische Kerne)
AnzPhysicalECores.l '1-basiert (phyische Kerne)
AnzLogicalPCores.l '1-basiert (logische Kerne)
AnzLogicalECores.l '1-basiert (logische Kerne)
'Array CoreType.b(2048) '0-basiert - 0=P-Core, >0=E-Core
aCoreTypeArray.i
aPCoreLogicalNumsString.i '*logische* Kerne auf P-Cores als Liste, z.B. "0,1,2,3,4,5,6,7" für die physischen P-Kerne 0-3 mit jeweils 2 Threads (für die Affinity Mask, die nutzt logische Kerne)
aECoreLogicalNumsString.i '*logische* Kerne auf E-Cores als Liste, z.B. "8,9,10,11" für die physischen E-Kerne 4-7 mit jeweils 1 Thread (für die Affinity Mask, die nutzt logische Kerne)
EndStructure 'S_CpuCores
ENDPBGLOBAL
pbPROC pbGetCPUCores(*CpuCores.S_CpuCores)
'das Ergebnis landet in der übergebenen Variable CpuCores.S_CpuCores
protected i.l,o.l,nKernel32.i,Offset.l,BufferSize.l,HasECores.b,CoreNum.l
protected RelationshipType.l,*Buffer,ReturnedLength.l,*slpie.S_SYSTEM_LOGICAL_PROCESSOR_INFORMATION_EX
protected PCoreLogicalNums$,ECoreLogicalNums$,dim CoreType.b(2048)
RelationshipType=0 'RelationProcessorCore
nKernel32=OpenLibrary(#PB_Any,"Kernel32.dll")
CallFunction(nKernel32,"GetLogicalProcessorInformationEx",RelationshipType,0,@ReturnedLength)
BufferSize=ReturnedLength
*Buffer=AllocateMemory(BufferSize)
CallFunction(nKernel32,"GetLogicalProcessorInformationEx",RelationshipType,*Buffer,@ReturnedLength)
Offset=0
*CpuCores\AnzPhysicalCores=0
*CpuCores\AnzThreads=0
*CpuCores\AnzPhysicalPCores=0
*CpuCores\AnzPhysicalECores=0
*CpuCores\AnzLogicalPCores=0
*CpuCores\AnzLogicalECores=0
HasECores=0
while Offset<BufferSize
*CpuCores\AnzPhysicalCores=*CpuCores\AnzPhysicalCores+1
*slpie=*Buffer+Offset
CoreType(*CpuCores\AnzPhysicalCores-1)=*slpie\EfficiencyClass
if *slpie\EfficiencyClass=0
*CpuCores\AnzThreads=*CpuCores\AnzThreads+1
*CpuCores\AnzPhysicalECores=*CpuCores\AnzPhysicalECores+1
*CpuCores\AnzLogicalECores=*CpuCores\AnzLogicalECores+1
else
*CpuCores\AnzThreads=*CpuCores\AnzThreads+2
*CpuCores\AnzPhysicalPCores=*CpuCores\AnzPhysicalPCores+1
*CpuCores\AnzLogicalPCores=*CpuCores\AnzLogicalPCores+2
HasECores=1
endif
Offset=Offset+*slpie\Size
wend
if HasECores=0 'dann wird für EfficiencyClass immer 0 zurückgegeben, das muss in diesem Fall also überall auf 1 gesetzt werden
for i=0 to *CpuCores\AnzPhysicalCores-1
CoreType(i)=1
next i
*CpuCores\AnzPhysicalPCores=*CpuCores\AnzPhysicalECores
*CpuCores\AnzPhysicalECores=0
*CpuCores\AnzLogicalPCores=*CpuCores\AnzLogicalECores
*CpuCores\AnzLogicalECores=0
*CpuCores\AnzThreads=*CpuCores\AnzThreads*2
endif
PCoreLogicalNums$=""
ECoreLogicalNums$=""
CoreNum=-1
for i=0 to *CpuCores\AnzPhysicalCores-1
if CoreType(i)=0 'E-Core
CoreNum=CoreNum+1
if ECoreLogicalNums$<>""
ECoreLogicalNums$=ECoreLogicalNums$+","
endif
ECoreLogicalNums$=ECoreLogicalNums$+str(CoreNum)
else 'P-Core
for o=1 to 2
CoreNum=CoreNum+1
if PCoreLogicalNums$<>""
PCoreLogicalNums$=PCoreLogicalNums$+","
endif
PCoreLogicalNums$=PCoreLogicalNums$+str(CoreNum)
next o
endif
next i
PokeS(*CpuCores\aPCoreLogicalNumsString,PCoreLogicalNums$,-1,#PB_Ascii)
PokeS(*CpuCores\aECoreLogicalNumsString,ECoreLogicalNums$,-1,#PB_Ascii)
for i=1 to 2048
PokeB(*CpuCores\aCoreTypeArray+(i-1),CoreType(i))
next i
CloseLibrary(nKernel32)
FreeMemory(*Buffer)
ENDPROC 'pbGetCPUCores
PROC PinToPCores
declare i%,iend%,CpuCores#,PCoreLogicalNums$,ECoreLogicalNums$,CoreTypes#,PCoreMask&
dim CpuCores#,S_CpuCores
PCoreLogicalNums$:=@Space$(10000)
ECoreLogicalNums$:=@Space$(10000)
CpuCores#.aPCoreLogicalNumsString&:=@addr(PCoreLogicalNums$)
CpuCores#.aECoreLogicalNumsString&:=@addr(ECoreLogicalNums$)
dim CoreTypes#,2048
CpuCores#.aCoreTypeArray&:=CoreTypes#
pbGetCPUCores(CpuCores#)
PCoreLogicalNums$:=@trim$(PCoreLogicalNums$)
if CpuCores#.AnzPhysicalPCores&>0
iend%:=@len(PCoreLogicalNums$,",")
for i%,1,iend%
PCoreMask&:=PCoreMask&+(2 ^ @val(@substr$(PCoreLogicalNums$,i%,",")))
endfor 'i%
~SetProcessAffinityMask(~GetCurrentProcess(),PCoreMask&)
endif
dispose CpuCores#,CoreTypes#
ENDPROC 'PinToPCores
PROC PinToECores
declare i%,iend%,CpuCores#,PCoreLogicalNums$,ECoreLogicalNums$,CoreTypes#,ECoreMask&
dim CpuCores#,S_CpuCores
PCoreLogicalNums$:=@Space$(10000)
ECoreLogicalNums$:=@Space$(10000)
CpuCores#.aPCoreLogicalNumsString&:=@addr(PCoreLogicalNums$)
CpuCores#.aECoreLogicalNumsString&:=@addr(ECoreLogicalNums$)
dim CoreTypes#,2048
CpuCores#.aCoreTypeArray&:=CoreTypes#
pbGetCPUCores(CpuCores#)
ECoreLogicalNums$:=@trim$(ECoreLogicalNums$)
if CpuCores#.AnzPhysicalECores&>0
iend%:=@len(ECoreLogicalNums$,",")
for i%,1,iend%
ECoreMask&:=ECoreMask&+(2 ^ @val(@substr$(ECoreLogicalNums$,i%,",")))
endfor 'i%
~SetProcessAffinityMask(~GetCurrentProcess(),ECoreMask&)
endif
dispose CpuCores#,CoreTypes#
ENDPROC 'PinToECores
PROC PinToOrigCores
~SetProcessAffinityMask(~GetCurrentProcess(),_OrigAffinityMask&)
ENDPROC 'PinToOrigCores
PROC PinToAllCores
~SetProcessAffinityMask(~GetCurrentProcess(),_SystemAffinityMask&)
ENDPROC 'PinToAllCores
@External("kernel32.dll","GetProcessAffinityMask",@External("kernel32.dll","GetCurrentProcess"),@Addr(_OrigAffinityMask&),@Addr(_SystemAffinityMask&))
PinToECores 'das Programm kann auf einem beliebigen E-Core laufen (gilt auch für Child-Prozesse!)
PinToPCores 'das Programm kann auf einem beliebigen P-Core laufen (gilt auch für Child-Prozesse!)
PinToAllCores 'das Programm kann auf allen Cores laufen (gilt auch für Child-Prozesse!)
PinToOrigCores 'das Programm ist auf Core 0 Thread 0 beschränkt (gilt auch für Child-Prozesse!)
Alles anzeigen