Hallo Roland.
Schon lange wünsche ich mir eine Progressbar in XProfan. Bisher habe ich das ganz gut mit einer INC machen können, das ist auch kein Problem. Allerdings könnte es problematisch werden, jetzt wo du das Multiprocessing eingebaut hast. Und gerade da ist eine Progressbar für einen Hintergrundprozess vielleicht gar nicht so verkehrt. Ich hab hier mal meine INC eingefügt, vielleicht kannst/willst du das noch einbauen, das ist vielleicht nicht viel:
Code
'1.0.0 (10.11.2006)
'Progressbar:
'..................
Def SetWindowTheme(3) !"uxtheme.dll","SetWindowTheme"
Subproc Create.Progressbar
'Erzeugt eine Progressbar (die meisten Parameter erklären sich von selbst)
'Style: $0=Unterbrochene Linie, $1=durchgezogene Linie (kein Einfluss bei WinXP mit aktivierten Styles)
' $0=Windows-Default,$2=Ohne Theme
' $0=Horizontal,$4=Vertikal
' $0=kein Rahmen,$8=Rahmen
' $0=von links nach rechts;$10=von rechts nach links
' Style wird durch Addieren der Einzelstyles ermittelt
'Color: Farbe des Balkens festlegen (als RGB(x,y,z)-Wert); -1=SystemDefault (kein Einfluss bei WinXP mit aktivierten Styles)
Parameters HWnd&,style&,color&,x&,y&,dx&,dy&
declare handle&,t&
handle&=Control("MSCTLS_PROGRESS32","",$50000000+TestBit(style&,0)+TestBit(style&,2)*4+TestBit(style&,3)*$800000,x&,y&,dx&,dy&,HWnd&,1001,%hInstance,TestBit(style&,4)*$400000)
case -1<>color&:sendmessage(handle&,$409,0,color&)
if TestBit(style&,1)
t&=UseDLL("uxtheme.dll")
if t&
SetWindowTheme(handle&,0,0)
FreeDLL t&
endif
endif
Return handle&
endproc
proc SetProgress
Parameters handle&,wert&
'Setzt den Füllstand (in Prozent) einer Progressbar
sendmessage(handle&,$402,wert&,0)
endproc
proc GetProgress
'Liest den aktuellen Füllstand (in Prozent) der Progressbar aus
Parameters handle&
Return sendmessage(handle&,$405,0,0)
endproc
proc SetProgressColor
'Ändert die Farbe der Fortschrittsbalkens
Parameters handle&,color&
sendmessage(handle&,$409,0,color&)
endproc
proc AddProgress
'Addiert den angegebenen Wert zum vorhandenen dazu
Parameters handle&,delta%
Return sendmessage(handle&,$403,delta%,0)
endproc
proc ProgressSetStep
'Setzt den Step für ProgressStep
Parameters handle&,wert%
Return sendmessage(handle&,$404,wert%,0)
endproc
proc ProgressStep
'Addiert einen Step zum vorhandenen Wert
Parameters handle&
Return sendmessage(handle&,$405,0,0)
endproc
Alles anzeigen
Viel wichtiger als das einzubauen wäre mir aber, dass die Kommunikation zum aufrufenden Programm klappt, wenn man ein anderes mit PExec aufruft.
Jac