Ich hatte hier (Python-Strings) Index-Zugriff für Strings wieder entdeckt.
In Pascal gibt es diesen Zugriff ja auch (sogar schreibend).
Ich hab das mal als
ErgebnisString = IdxStr(s,"[2:5]")
nachgebaut.
Natürlich hat Profan dafür seit Version 1.x die Funktion Mid$( string, start, länge ).
Bei Python geht das etwas anders.
- die Strings mit Basis 0 anzusprechen
- es wird nicht die Länge, sondern der Zielpunkt minus eins angegeben
- die tollen Möglichkeiten beinhalten LEFT/MID/RIGHT
Hab das Beispiel mal in Datei umgeleitet...
ZitatAlles anzeigens=Python -- als String
{P} - IdxStr(s,'[0]')sollte sein: P(6/6)
{n} - IdxStr(s,'[5]')sollte sein: n(6/6)
{n} - IdxStr(s,'[-1]')sollte sein: n(6/6)
{o} - IdxStr(s,'[-2]')sollte sein: o(6/6)
{P} - IdxStr(s,'[-6]')sollte sein: P(6/6)
{Py} - IdxStr(s,'[0:2]')sollte sein: Py(6/6)
{tho} - IdxStr(s,'[2:5]')sollte sein: tho(6/6)
{Py} - IdxStr(s,'[:2]')sollte sein: Py(6/6)
{on} - IdxStr(s,'[4:]')sollte sein: on(6/6)
{on} - IdxStr(s,'[-2:]')sollte sein: on(6/6)
{on} - IdxStr(s,'[4:42]')sollte sein: on(6/6)
{} - IdxStr(s,'[42:]')sollte sein: ''(6/6){Python} - [:2]+[2:]sollte sein: Python
{Python} - [:4]+[4:]sollte sein: Python
// -----------------------------------------------------------------------
$IFDEF VER12.0
Proc MyRange
/*
Range kann sein: [], [3], [3:5], [3:], [:5], [-3], [-3:-5], [-3:], [:-5]
[] - gibt alles zurück
Die Range wird null-basiert angegeben. Die eckigen Klammern können entfallen.
Das Ergebnis sind Stringlänge und Startposition mit eins-Basis.
*/
Parameters String IdxS, Long MaxLen
Declare Long ErgRange[], b,e,Le, Int Posi
// erst alles auf Gesamtlänge/-Range setzen
Le = MaxLen : b = 0 : e = Le
// alle führenden, folgenden und enthaltenen Leerzeichen entfernen
IdxS = Translate$(IdxS," ","")
// wenn vorhanden, die eckigen Klammern entfernen
Case (Left$(IdxS,1)="[") and ((Right$(IdxS,1)="]")) : IdxS = Mid$(IdxS,2,Len(IdxS)-2)
If (Len(IdxS) > 0) and (MaxLen > 0)
Posi = InStr(":",IdxS)
If Posi = 0
// --- nur ein Index angegeben (ein Zeichen) [3], [-3]
// --- - wenn (b<0) oder (b>=e), dann Leerstring
Le = 1
b = Val(IdxS) : Case b < 0 : b = MaxLen + b
Case (b < 0) or (b >= e) : Le = 0
Else
// KEIN "ElseIf", denn...
// hier wird die Grenzprüfung für alle Fälle am Ende vorgenommen
If Posi = 1
// --- von vorne beginnen ... [:5], [:-5]
b = 0
e = Val(SubStr$(IdxS,2,":")) : Case e < 0 : e = MaxLen + e
ElseIf Posi = Len(IdxS)
// --- ... bis zum Ende [3:], [-3:]
b = Val(SubStr$(IdxS,1,":")) : Case b < 0 : b = MaxLen + b
e = MaxLen
Else
// --- [3:5], [-3:-5], [-3:9]
b = Val(SubStr$(IdxS,1,":")) : Case b < 0 : b = MaxLen + b
e = Val(SubStr$(IdxS,2,":")) : Case e < 0 : e = MaxLen + e
EndIf
// --- - wenn (b<0) oder (b>=e), dann Leerstring
// --- - wenn (e>=MaxLen), dann Gesamtstring
// --- - sonst (e-b+1) Zeichen
If (b < 0) or (b >= e)
Le = 0
ElseIf (e > MaxLen)
Le = MaxLen
Else
Le = e - b
EndIf
EndIf
EndIf
ErgRange[0] = Le
ErgRange[1] = b + 1 // jetzt also Beginn von 1 bis MaxLen
Return ErgRange[]
EndProc
Proc IdxStr
Parameters String s, IdxS
Declare Long theRange[], String erg
theRange[] = MyRange(IdxS,Len(s))
If theRange[0] > 0
erg = Mid$(s,theRange[1],theRange[0])
Else
erg = ""
EndIf
Return erg
EndProc
$ENDIF
// -----------------------------------------------------------------------
// -----------------------------------------------------------------------
// -----------------------------------------------------------------------
' Test - Areal
$IFDEF VER12.0
Declare String s
// Ranges in Python-Form (also nullbasiert)
s = "Python"
Cls
Print "s=";s," -- als String"
Print "{";IdxStr(s,"[0]");"}";Tab(10);"- IdxStr(s,'[0]')";Tab(33);"sollte sein: P";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[5]");"}";Tab(10);"- IdxStr(s,'[5]')";Tab(33);"sollte sein: n";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[-1]");"}";Tab(10);"- IdxStr(s,'[-1]')";Tab(33);"sollte sein: n";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[-2]");"}";Tab(10);"- IdxStr(s,'[-2]')";Tab(33);"sollte sein: o";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[-6]");"}";Tab(10);"- IdxStr(s,'[-6]')";Tab(33);"sollte sein: P";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[0:2]");"}";Tab(10);"- IdxStr(s,'[0:2]')";Tab(33);"sollte sein: Py";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[2:5]");"}";Tab(10);"- IdxStr(s,'[2:5]')";Tab(33);"sollte sein: tho";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[:2]");"}";Tab(10);"- IdxStr(s,'[:2]')";Tab(33);"sollte sein: Py";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[4:]");"}";Tab(10);"- IdxStr(s,'[4:]')";Tab(33);"sollte sein: on";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[-2:]");"}";Tab(10);"- IdxStr(s,'[-2:]')";Tab(33);"sollte sein: on";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[4:42]");"}";Tab(10);"- IdxStr(s,'[4:42]')";Tab(33);"sollte sein: on";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "{";IdxStr(s,"[42:]");"}";Tab(10);"- IdxStr(s,'[42:]')";Tab(33);"sollte sein: ''";Tab(53);"(";Len(s);"/";SizeOf(s);")"
Print "\n\n"
s = "Python"
Print "{";IdxStr(s,"[:2]");IdxStr(s,"[2:]");"}";Tab(10);"- [:2]+[2:]";Tab(33);"sollte sein: Python"
Print "{";IdxStr(s,"[:4]");IdxStr(s,"[4:]");"}";Tab(10);"- [:4]+[4:]";Tab(33);"sollte sein: Python"
WaitKey
End
$ELSE
Cls
Print "\nBitte mit XProfan X2 oder höher testen..."
WaitKey
End
$ENDIF
// -----------------------------------------------------------------------
// -----------------------------------------------------------------------
Alles anzeigen