Hallo,
habe mich mal mit JSON beschäftigt.
Hier ist eine ToDo-Liste. Das Besondere daran :
Man kann nicht nur Aktionen für den jeweiligen Tag eingeben.
Bei der Aktion z.b. Einkauf ist es ja optimal, Artikel in die rechte Liste einzutragen oder auch zu drucken.
Einen Nachteil hat das ganze noch. Um keinen Fehler zu bekommen, muß man zuerst auf den Wochentag
klicken, damit das Programm weiß, welches Objekt gerade aktiv ist. Ich weiß noch nicht, wie ich das in einer
Struktur zusammenhalte.
Am Wochende kann man dann die . .json Datei löschen und mit einer neuen Woche anfangen.
Code
Declare Handle btn1, btn2, btn3, edit1, edit2, tv
Declare Long ende, js, xs, item, subitem, obj, jtage[5]
Declare String datei, ueberschrift, jitem, name, txt, Tage[5]
Declare Long p, y, anz, liste
WindowTitle "Wochen - Liste"
Window 600, 500
btn1 = Create("Button", %HWnd, "Add", 10, 10, 60, 25)
btn2 = Create("Button", %HWnd, "Drucken", 380, 10, 60, 25)
btn3 = Create("Button", %HWnd, "Ende", 160, 10, 60, 25)
Create("Text", %HWnd, "Aktion", 10, 50, 60, 25)
edit1 = Create("Edit", %HWnd, "", 100, 50, 180, 25)
Create("Text", %HWnd, "Liste", 300, 10, 50, 25)
edit2 = Create("MultiEdit", %HWnd, "", 300, 40, 240, 130)
tv = Create("TreeView", %HWnd, 0, 10, 150, 240, 150)
Tage[0] = "Montag"
Tage[1] = "Dienstag"
Tage[2] = "Mittwoch"
Tage[3] = "Donnerstag"
Tage[4] = "Freitag"
Tage[5] = "Samstag"
ende = 0
datei = "Wochenplan.Json"
IfNot FileExists(datei)
InitJson()
InitTree()
Else
js = Create("JSON", datei)
JsonInitTree()
EndIf
WhileNot ende
WaitInput
If Clicked(btn1)
'Add an item
If IndexOf(Tage[], jitem) > -1
TreeView("InsertItem", tv, item, 0, GetText$(edit1))
TreeView("SetChildren", tv, item, 1)
obj = Json("GetObject", js, jitem)
xs = Create("Json")
liste = Json("NewList")
txt = GetText$(edit2)
If Len(txt) > 0
WhileLoop 0, GetCount(edit2) - 1
Json("AddString", liste, GetString$(edit2, &LOOP))
EndWhile
EndIf
Json("AddList", xs, "Liste", liste)
JSon("AddObject", obj, GetText$(edit1), xs)
EndIf
ElseIf Clicked(btn2)
' Drucken
anz = GetCount(edit2)
y = 10
StartPrint
DrawText 10, y, ueberschrift
Inc y, 14
DrawText 10, y, "-----------------------"
Inc y, 14
WhileLoop 0, anz - 1
DrawText 10, y, GetString$(edit2, &LOOP)
Inc y, 14
EndWhile
EndPrint
ElseIf Clicked(btn3)
Json("WRITE", js, datei)
ende = 1
ElseIf Clicked(tv)
item = TreeView("GetSelected", tv)
TreeView("Expand", tv, item, 3)
jitem = GetText$(tv, item)
p = IndexOf(tage[], jitem)
If p > -1
obj = Json("GetObject", js, jitem)
EndIf
If p = -1
ueberschrift = jitem
subitem = Json("GetObject", obj, jitem)
liste = Json("GetList", subitem, "Liste")
anz = Json("Count", liste)
SetText edit1, jitem
If anz > 0
Txt = ""
SetText edit2, ""
WhileLoop 0, anz - 1
txt = txt + Json("GetString", liste, &LOOP) + Chr$(13) + Chr$(10)
EndWhile
SetText edit2, txt
EndIf
EndIf
EndIf
EndWhile
Proc InitJson
js = Create("Json")
WhileLoop 0, 5
jtage[&LOOP] = Create("Json")
Json("AddObject", js, Tage[&LOOP], jtage[&LOOP])
EndWhile
EndProc
Proc InitTree
WhileLoop 0, 5
TreeView("InsertItem", tv, 0, 0, Tage[&LOOP])
TreeView("SetChildren", tv, 0, 1)
EndWhile
EndProc
Proc JsonInitTree
Declare Long x, i, h
anz = Json("Count", js)
WhileLoop 0, anz - 1
name = Json("Name", js, &LOOP)
h = TreeView("InsertItem", tv, 0, 0, name)
obj = Json("GetObject", js, name)
x = Json("Count", obj)
For i, 0, x - 1
If Json("Type", obj, i) <> 5
TreeView("InsertItem", tv, h, 0, Json("Name", obj, i))
TreeView("SetChildren", tv, h, 1)
EndIf
EndFor
EndWhile
EndProc
End
Alles anzeigen
Was noch fehlt, ist das Ändern und Löschen der verschiedenen Objekte.
Naja, probiert es mal aus. Vielleicht habt ihr noch Ideen.