Modelleisenbahner haben manchmal das Problem, eine passende Nummer für selbstgebaute Lokomotiven zu finden. Ab 1968 bei der DB und ab 1970 auch bei der DR wurden edv-gerechte Lokomotivnummern eingeführt. Diese sind gekennzeichnet durch eine Selbstkontrollziffer, die durch Bindestrich abgesetzt an die Fahrzeugnummer angehängt ist. Diese dient dazu, Fehler bei der Übermittlung der Fahrzeugnummer zu vermeiden. Das nachfolgende Programm kann diese Kontrollziffer berechnen, oder wenn man diese mit eingibt, deren Richtigkeit feststellen. Die Checkbox DR sollte ensprechend gesetzt sein, da beide Bahnverwaltungen die noch vorhandenen Dampflokomotiven bei der Nummernvergabe unterschiedlich behandelt hatten.
Code
$H WINDOWS.PH
Declare Int IsDR
Declare String LokNr, TLokNr
Declare Handle Edit, OK, Hlp, DRCheck
Declare Int Ende, Flag
Var String Title = "EDV-Loknummern"
Proc Normalise
Parameters String LokNr
If IsDR
If (Left$(LokNr,1) = "1") Or (Left$(LokNr,1) = "2")
LokNr = Ins$(" ",LokNr,4)
Else
LokNr = Ins$(" ",LokNr,3)
EndIf
Else
LokNr = Ins$(" ",LokNr,4)
EndIf
Case Len(LokNr) = 8 : LokNr = Ins$("-",LokNr,8)
Return LokNr
EndProc
Proc CalcPruef
Parameters String LokNr
Declare Int Teil, Pruef, String sTeil
WhileLoop 6
Teil = Val(Mid$(LokNr,&Loop,1))
CaseNot TestBit(&Loop, 0) : Teil = Teil * 2
If Teil > 9
sTeil = Str$(Teil)
Teil = Val(Left$(sTeil,1)) + Val(Right$(sTeil,1))
EndIf
Pruef = Pruef + Teil
EndWhile
Pruef = Pruef Mod 10
Pruef = 10 - Pruef
While Pruef > 9
Pruef = Pruef - 10
EndWhile
Return Pruef
EndProc
Proc ConvertLokNr
Parameters String LokNr
LokNr = Trim$(LokNr)
LokNr = Translate$(LokNr," ","")
LokNr = Translate$(LokNr,"-","")
Return LokNr
EndProc
Proc CheckPruef
Parameters String LokNr
Declare Int Pruef, Test, String Ret
LokNr = ConvertLokNr(LokNr)
If (Len(LokNr) < 6) Or (Len(LokNr) > 7)
Flag = 4
Return "Die Eingabe " + LokNr +" ist ungültig"
Else
Pruef = CalcPruef(LokNr)
If Len(LokNr) < 7
LokNr = LokNr + "-" + Str$(Pruef)
Flag = 1
Ret = Normalise(LokNr) + "\nist die vollständige Loknummer,\ndie Kontrollziffer " + Str$(Pruef) + " wurde berechnet"
Else
Test = Val(Right$(LokNr,1))
If Test = Pruef
Flag = 2
Ret = Normalise(LokNr) + "\nist gültig"
Else
Flag = 3
Ret = Normalise(LokNr) + "\nist ungültig"
EndIf
EndIf
EndIf
Return Ret
EndProc
Proc MeldeText
Parameters String Text
If Text = ""
Text = "Bitte Loknummer eingeben"
Flag = 6
EndIf
Rectangle 4,32-(Width(%HWnd,0)-4),80
If Flag = 6
TextColor RGB(128,128,128),-1
ElseIf Flag > 2
TextColor RGB(250,0,0),-1
Else
TextColor 0,-1
EndIf
DrawText 6,34,Width(%HWnd,0)-8,78,Text,0
EndProc
Proc Auswerten
IsDR = GetCheck(DrCheck)
LokNr = GetText$(Edit)
MeldeText CheckPruef(LokNr)
EndProc
Proc Hilfe
Declare String Hilfe
Hilfe = "Die Loknummer kann mit und ohne Kontrollziffer eingegeben werden\n" +\
"\t118059\n\t118 059\n\t1180595\n\t118 059-5\nsind gültige Eingaben.\n\n" +\
"Die Auswahl DR/DB muß nur bei Dampfloks gesetzt sein, um die vollständige " +\
"Nummer in der korrekt anzuzeigen.\n\n" +\
"Die Loknummer muß vollständig sein, auch alle führenden Nullen müssen " +\
"korrekt angegeben werden.\n\n" +\
"Bei fehlender Kontrollziffer wird diese berechnet. Ist die Kontrollziffer " +\
"angegeben, wird diese auf Gültigkeit überprüft."
MessageBox(Hilfe,Title,64)
SetFocus(Edit)
EndProc
WindowStyle 536
WindowTitle Title
Window 338,116
CLS RGB(200,230,230)
SetDialogFont ~GetStockObject(~Ansi_Var_Font)
Edit = Create("Edit",%HWnd,"",4,6,102,18)
OK = Create("Button",%HWnd,"Prüfen",108,4,88,24)
DRCheck = Create("CheckBox",%HWnd,"DR/DB",202,6,102,18)
Hlp = Create("Button",%HWnd,"?",308,4,20,24)
UseIcon "A"
UseFont "Verdana",14,0,0,0,0
SetFont Edit,0
SetFont Hlp,0
UsePen 0,1,RGB(0,220,220)
UseBrush 1,RGB(255,255,208)
SetFocus(Edit)
SetCheck DRCheck,1
WhileNot Ende
If GetCheck(DrCheck)
SetText DrCheck,"DR [DR/DB]"
Else
SetText DrCheck,"DB [DR/DB]"
EndIf
TLokNr = GetText$(Edit)
If (Len(TLokNr) < 6) And (Not(InStr(" ",TLokNr))) Or ((Len(TLokNr) < 7) And (InStr(" ",TLokNr)))
MeldeText ""
EnableWindow OK, 0
Else
If (LokNr <> "") And (LokNr <> TLokNr)
Meldetext ""
EndIf
EnableWindow OK,1
EndIf
WaitInput
If Clicked(OK)
Auswerten
ElseIf Clicked(Hlp)
Hilfe
ElseIf %Key = 13
Auswerten
ElseIf %Key = 2
Ende = 1
EndIf
EndWhile
Alles anzeigen
Gruß Volkmar