Temp und Recent Ordner beim Start löschen

  • Hallo!

    Wie kann ich es einstellen, dass ich den Temp und den Recent Ordner beim Start löschen lassen kann?

    Liebe Grüße

    • Anzeige

    Hallo!

    Wenn du gerade an deiner Website arbeitest oder dein aktuelles Hosting überdenkst: Wir betreiben mit NetzLiving eine Hosting-Plattform, die speziell auf Performance, Sicherheit und einfache Verwaltung ausgelegt ist.

    • ✔️ Schnelle Ladezeiten (optimiert für WordPress, WoltLab & Co.)
    • ✔️ Deutsche Server & DSGVO-konform
    • ✔️ Persönlicher Support (kein 0815-Ticket-System)

    Mehr erfahren

  • Hallo!


    Am besten und einfachsten wäre es, wenn du dir das Programm TweakUI holst. Da kannst du viele Systemeinstellungen vornehmen und unter anderem auch die von dir gewünschten Sachen einstellen.


    mfg raser

  • Das konnte ich finden, allerdings weiß ich nicht, ob es bei deinem Betriebssystem funktioniert.
    Es wäre schön, wenn du einen kleinen Erfahrungsbericht schreiben könntest, eine genau Anleitung und unter welchen Betriebssystem wäre schön.
    Ich habe einen FAQ Beitrag geschrieben, der unter Windows 98 den Recent bei Neustart löscht, den könnte ich dann etwas ausbauen.
    Das ist er:
    https://www.paules-pc-forum.de/phpBB2/topic,5875.html

    1. Versuch

    2. Versuch

    Zitat

    Man klickt auf "Start", dann auf "Ausführen", gibt im Feld "regedit" ein und klickt dann auf "OK".
    Das Fenster des Registrierungseditors öffnet sich nun.

    HKEY_CURRENT_USER\ Software\ Microsoft\ Windows\ Current Version\ Explorer\ User Shell Folder

    Auf der rechten Seite vom "User Shell Folder" enthält der Eintrag mit dem Namen "Recent" den Wert "...". Diesen Eintrag "Recent" sollte man entweder löschen oder doppelt anklicken und die drei Punkte manuel löschen und mit OK bestätigen, "Recent" wäre dann leer, aber immer noch vorhanden (für den Fall, dass bei manchen dann die Registry spinnt).

    Mit freundlichen Grüßen
    Michi

  • Als erstes suchst Du auf deiner Festplatte nach der richtigen index.dat Datei!
    Zum entfernen der Datei gehe ins DOS-Modus (F8 beim booten),
    dann in den windows\cookies ordner,
    dort siehtst Du die index.dat .
    (Dort werden soweit ich weiß alle Userdaten gespeichert!

    Diese Datei löscht man einfach und erstellt einen Ordner mit der gleichen Bezeichnung also index.dat
    und schon werden cookies zwar aktzeptiert aber nicht mehr gespeichert
    Eine weitere Methode um gegen Cookies vorzugehen!
    Einfach in die autoexec.bat folgende Zeilen hinzufügen!

    DELTREE.EXE /Y C:\WINDOWS\TEMP\*.*
    DELTREE.EXE /Y C:\WINDOWS\TEMPOR~1\*.*
    DELTREE.EXE /Y C:\WINDOWS\COOKIES\*.*
    DELTREE.EXE /Y C:\WINDOWS\VERLAUF\*.*

    Es werden dann alle Temporären Dateien sowie der Verlauf des IE und alle Cookies beim Hochfahren des Rechners automatisch gelöscht.
    Am Anfang muss > @echo off < stehen!

  • Hier habe ich mal was für Windows 2000 zusammengefummelt.
    Es werden dabei 3 Ordner (Recent, Temp unter Lokale Einstellungen und Temp unter Windows) innerhalb des Ordners C:\Dokumente und Einstellungen\Benutzer gelöscht sammt Unterordner wobei die Ordner danach wieder erstellt werden aber dann leer sind.
    Welche Ordner gelöscht werden ist abhängig vom Benutzernamen und der komplette Pfad steht in der Variablen %USERPROFILE% drin.

    Hier das Beispiel:
    cd %userprofile%
    rd Recent /s/q
    md Recent
    attrib +r +h Recent
    rd "Lokale Einstellungen\Temp" /s/q
    md "Lokale Einstellungen\Temp"
    rd Windows\Temp /s/q
    md Windows\Temp
    cd\

    Wer möchte, das auch der Inhalt der Temporären Internet-Dateien gelöscht wird, kann auch noch folgendes vor der letzten Zeile einfügen wobei das den Traffic erhöhen kann wenn man oft auf bestimmten Seiten sich aufhält:

    rd "Lokale Einstellungen\Temporary Internet Files" /s/q
    md "Lokale Einstellungen\Temporary Internet Files"

    Das gleiche gilt für die Cookies:

    rd Cookies /s/q
    md Cookies

    Am besten erstellt man sich eine BAT-Datei, z. B. DELTEMP.BAT, speichert die irgend wo, z. B. auf C:\ und macht im Autostart einen Link dazu.
    Damit es bei allen Benutzern funktioniert kann man auch in der Registrie einen Verweis unter HKLM\Software\Microsoft\Windows\CurrentVersion\Run einfügen.

    Ob es bei Windows XP auch geht bzw. ob diese Unterordner Recent, Temp in Lokele Einstellungen und Temp in Windows auch so angeordnet sind, hab ich noch nicht abgecheckt.

    Ich habe das zwar getestet aber Benutzung auf eigene Gefahr!!!

    Gruß
    Andi

  • @Hänker
    Ich habe das ohne Echo Off eingegeben und es funktioniert, wozu also?

    Und so ganz habe ich das nicht verstanden, muss es denn so aussehen?

    @echo off DELTREE.EXE /Y C:\WINDOWS\TEMP\*.*
    @echo off DELTREE.EXE /Y C:\WINDOWS\TEMPOR~1\*.*
    @echo off DELTREE.EXE /Y C:\WINDOWS\COOKIES\*.*
    @echo off DELTREE.EXE /Y C:\WINDOWS\VERLAUF\*.*

    Mit freundlichen Grüßen
    Michi

  • Zitat von michi-w.


    @echo off DELTREE.EXE /Y C:\WINDOWS\TEMP\*.*
    @echo off DELTREE.EXE /Y C:\WINDOWS\TEMPOR~1\*.*
    @echo off DELTREE.EXE /Y C:\WINDOWS\COOKIES\*.*
    @echo off DELTREE.EXE /Y C:\WINDOWS\VERLAUF\*.*

    Wenn du das so hinschreibst, werden die Befehle nicht ausgeführt!


    mfg raser

  • Nein!
    Hänker meinte, den Echo off als erste Zeile einzugeben mit nen Klammeraffen:

    @ECHO OFF

    Dadurch ist das Echo, also das Zeigen der nächsten Befehlszeile, ausgeschaltet.
    Alle nachfolgenden Befehle ganz normal.
    Im Endeffekt so:

    @ECHO OFF
    DELTREE.EXE /Y C:\WINDOWS\TEMP\*.*
    DELTREE.EXE /Y C:\WINDOWS\TEMPOR~1\*.*
    DELTREE.EXE /Y C:\WINDOWS\COOKIES\*.*
    DELTREE.EXE /Y C:\WINDOWS\VERLAUF\*.*

    Gruß
    Andi

  • @Schwabenpfeil:
    Die Variable %USERPROFILE% hat ihre Existenz unter Windows 2000, XP und evtl. auch auf Windows NT.
    Sie wird vom System generiert und gesetzt und beinhaltet nichts anderes als den Pfad zu dem momentanen Benutzerprofil.
    Wenn man sich gerade mit Administrator angemeldet hat steht in dieser Variablen in einem deutschen Windows 2000 "C:\Dokumente und Einstellungen\Administrator" drinnen wo auch die ganzen Temporären Ordner und Dateien des Benutzers Administrator enthalten sind.
    Starte unter Win2000/XP unter ausführen "CMD".
    Gib ein: "Echo %userprofile%".
    Dann erscheint: "C:\Dokumente und Einstellungen\Benutzername".
    Benutzername steht dabei für Administrator oder Hinz oder Kunz.
    Je nach dem, wie Dein Anmeldename ist.

    Ich verwende in meinem Beispiel den Befehl "CD %USERPROFILE% dazu um in das momentane Benutzerverzeichnis zu schalten um dort dann mit den nachfolgenden Befehlen die ganzen Temporären Dateien zu löschen.

    Mit dem Befehl SET in der DOS-Box wirst Du sehen, was es sonst noch alles für Systemvariablen gibt.

    Gruß
    Andi

  • Hey Danke!
    Vor allem das mit dem Guru. :)

    Ich erweitere das noch so, das es sich beim manuellen Start selbst in die Registry reinschreibt und noch ne Batch-Datei zum entfernen aus der Registry.

    Das mit WinXP check ich auch noch ab.

    Aber denk noch an das Beispiel vom Hänker!

    Gruß
    Andi

  • Hallo Guru,

    vielen Dank für die Erklärung! Die Funktion des Scriptes ist mir klar, ich wusste nur nicht an welcher Stelle die Variable definiert wird. Obwohl, hätte ich mal richtig nachgedacht... :D

    Gruß
    Schwabenpfeil!

    ************** Nachtrag **************
    Guru und Hänker, wenn Ihr noch mehr solchen Scripte habt die uns den Windows-Alltag etwas erleichern können, dann nur her damit! :D Wir fügen die Beiträge dann gerne in die FAQs ein und auch in die Tipps & Tricks Datenbank!

  • So, jetzt habe ich das ganze noch ein bißchen überarbeitet!
    Hier das komplette Programm:
    --------------------------------------------
    @echo off
    set Pfad=%SystemDrive%
    if exist %Pfad%\deltemp.bat goto NoInstall
    echo Das Programm wird in das Laufwerk %Pfad%\ installiert ...
    copy deltemp.bat %Pfad%\
    attrib +r +s %Pfad%\deltemp.bat

    :NoInstall
    if exist %Pfad%\deltemp.reg goto NoReg
    echo Das Programm wird zum automatischen Start in die Registry eingetragen ...
    set Datei=%Pfad%\deltemp.reg
    echo REGEDIT4>%Datei%
    echo [HKEY_LOCAL_MACHINE\SOFTWARE\Microsoft\Windows\CurrentVersion\Run]>>%Datei%
    echo "Del Temp Files"="%Pfad%\\DelTemp.bat">>%Datei%
    regedit /s %Datei%
    attrib +r +s %datei%

    :NoReg
    echo Die Temporaeren Dateien werden entfernt ...

    set Pfad=%Temp%
    set Return=DelTemp2
    goto DelDir

    :DelTemp2
    set Pfad=%userprofile%\Windows\Temp
    set Return=DelRecent
    goto DelDir

    :DelRecent
    set Pfad=%userprofile%\Recent
    If exist "%Pfad%\." attrib -r -h "%Pfad%"
    set Return=DelTempInetFiles
    goto DelDir
    attrib +r +h "%Pfad%"

    :DelTempInetFiles
    set Pfad=%userprofile%\Lokale Einstellungen\Temporary Internet Files
    set Return=DelCookies
    rem goto DelDir

    :DelCookies
    set Pfad=%userprofile%\Cookies
    set Return=DelTemp3
    rem goto DelDir

    :DelTemp3
    set Pfad=%SystemRoot%\Temp
    set Return=Ende

    :DelDir
    if not exist "%Pfad%\." goto %Return%
    rd "%Pfad%" /s/q
    if not exist "%Pfad%\." md "%Pfad%"
    goto %Return%

    :Ende

    --------------------------------------------

    Es ist jetzt so aufgebaut, das es die Inhalte aller möglichen Temp-Ordner (Temp in Benutzer\Lokale Einstellungen, Benutzer\Windows und im SystemRoot (meistens C:\WINNT\Temp)) und den Inhalt des Recent-Ordners entfernt.
    Dabei wird auch vorher in dem Unterprogramm "DelDir" geprüft, ob der jeweilige Ordner vorhanden ist damit nach dem entfernen eines Temp-Ordners nicht unnötige Ordner entstehen.
    Beim ersten Start des Scripts kopiert sich das Script in das SystemDrive, normalerweise C:\, generiert die Datei DELTEMP.REG und setzt mittels Regedit einen Eintrag "Del Temp Files" unter Run in der Registry damit es bei jeder Anmeldung an Windows gestartet wird um das System sauber zu halten.
    Wie schon gesagt werden nur die Temporären Dateien und die Dateien im Ordner Recent des gerade anmeldenden Benutzers entfernt.
    Man kann sich auch die Temporären Internet Dateien und/oder die Cookies entfernen lassen.
    Da in den Cookies auch Automationen wie für hier die automatische Anmeldung enthalten sind und beim löschen der Temporären Internet Dateien der Traffic steigen kann habe ich in den Abschnitten zum löschen dieser vor dem Befehl "goto DelDir" ein "REM" davor gesetzt und die Entscheidung bleibt bei euch und könnt das "REM" dann löschen.

    Damit das mit dem Instalieren in das SystemDrive und dem automatischen Start funktioniert, muß das Script UNBEDINGT "DELTEMP.BAT" genannt werden.

    Wer das Script später löschen möchte sollte in den Ordneroptionen des Explorers die Option "Geschützte Systemdateien ausblenden" aus machen damit er es findet.

    Ach ja: Unter Windows XP ist der Aufbau so wie bei Windows 2000 und das läuft auch unter Windows XP.

    Und wie immer, Benutzung auf eigene Gefahr!

    Gruß
    Andi

Jetzt mitmachen!

Sie haben noch kein Benutzerkonto auf unserer Seite? Registrieren Sie sich kostenlos und nehmen Sie an unserer Community teil!