Habe hier mal den Code von Andreas Miethe etwas für ältere Profanversionen zurechtgefummelt und mit Abbruchfunktion versehen:
Code
'###############################################
'# Autor : ampsoft (Andreas Miethe) #
'# Umgeschrieben von: AHT #
'# Datum : 11.02.2012 #
'# Thema : Rekursive Dateisuche #
'# Gepostet für : [URL='http://www.paules-pc-forum.de']www.paules-pc-forum.de[/URL] #
'# XProfan-Version : XProfan9 #
'###############################################
'Achtung! Lauffähig erst ab Vista!!!
$H windows.ph
$H messages.ph
DEF GetDlgCtrlID(1) !"USER32.dll","GetDlgCtrlID"
DEF ButtonClicked(1) GetDlgCtrlID(@&(1)) = (%MENUITEM * -1)
Declare DLL&, Text&, Gefunden&, Liste&, Anzahl&, hProcess&
Declare Buffer$, Time&, StartPfad$, Dateimaske$, Abbrechen&
Declare Abbruch&
Dll& = UseDLL("DbgHelp.dll","")
clearlist
If ~GetProcAddress(Dll&,"EnumDirTree")
Declare Ende&
Windowstyle 536
WINDOW 0, 0 - 640, 440
USERMESSAGES $10
~SetClassLong(%hwnd,~GCL_STYLE,(~getClassLong(%hwnd,~GCL_STYLE)- ~CS_HREDRAW - ~CS_VREDRAW))
CLS ~GetSysColor(~Color_BTNFACE)
WindowTitle "Rekursive Dateisuche"
SetDialogFont ~GetStockObject(~DEFAULT_GUI_FONT)
Text& = Create("TEXT",%hwnd,"",0,0,width(%hwnd),24)
Gefunden& = Create("TEXT",%hwnd,"",0,28,width(%hwnd),24)
Abbruch& = Create("Button",%hwnd,"suchen",10,height(%hwnd)-60,200,30)
Liste& = Create("Listbox",%hwnd,"",10,100,width(%hwnd)-20,height(%hwnd)-180)
hProcess& = ~GetCurrentProcess()
Buffer$ = space$(100)
Else
MessageBox("Keine Unterstützung gefunden","Fehler",0)
End
EndIf
While %UMESSAGE<>$10
IF %UMESSAGE<>$10
Waitinput
endif
If ButtonClicked(Abbruch&)
SetMenuitem 0
SendMessage(Liste&, ~LB_RESETCONTENT, 0, 0)
Dateien_suchen
endif
wend
End
Proc Dateien_suchen
Anzahl& = 0
Settext Gefunden&,""
CLS ~GetSysColor(~Color_BTNFACE)
abbrechen& = 0
Dateimaske$ = Input$("Nach welchen Dateien soll gesucht werden?","Dateimaske:", "*.EXE")
StartPfad$ = Input$("Nach welchen Pfad soll die Suche beginnnen?","StartPfad:", "C:\")
Settext Abbruch&,"abbrechen"
External("Dbghelp.dll", "SymInitialize", hProcess&, 0, 0)
SendMessage(Liste&,~WM_SETREDRAW,0,0)
Repaint
Settext Text&,"Warten bitte...."
Time& = ~GetTickCount()
External("Dbghelp.dll", "EnumDirTree",hProcess&,addr(StartPfad$),addr(Dateimaske$),0,ProcAddr("EnumDirTreeProc",2), Liste&)
SendMessage(Liste&,~WM_SETREDRAW,1,0)
Repaint
External("Dbghelp.dll", "SymCleanup", hProcess&)
Settext Abbruch&,"suchen"
External("shlwapi.dll","StrFromTimeIntervalA",Addr(Buffer$),100, Int(~GetTickCount() - Time&),12)
Settext Text&,Buffer$
Settext Gefunden&,"Suche beendet : " + Str$(Anzahl&) + " Dateien gefunden die dem Suchkriterium entsprechen"
SendMessage(Liste&,~WM_SETREDRAW,1,0)
Repaint
endproc
Proc EnumDirTreeProc
PARAMETERS PPath&,CData&
Declare Path$
Path$ = String$(PPath&,0)
AddString(CData&,Path$)
SetText Text&,Path$
Inc Anzahl&
If ButtonClicked(Abbruch&)
abbrechen& = 1
SetMenuitem 0
endif
Case %UMESSAGE = $10 : abbrechen& = 1
Return abbrechen&
EndProc
Alles anzeigen
Gerade für XProfan ist das eine recht geniale Lösung von Andreas, leider erst ab Vista, wegen der EnumDirTree API, die es auf älteren Betriebsystemen nicht gibt. Die komplette Dateisuche wird von Windows übernommen und läuft nicht über XProfan Code - viel schneller geht es also nicht.